bewegte menüs

...sollte vollkommen egal sein ob nun 3 svcds oder dvd source. und ob man nun adobe premiere nimmt oder media studio bleibt auch dasselbe. du kannst das also so wie im guide beschrieben machen, sollte funktionieren.

P.S: übrigends echt nicht schlecht gemacht der guide.

Zitat

Originally posted by thargor
Ja, aber wie gesagt, in dem Guide wird ja davon ausgegangen, das man eine DVD als Source zugrunde hat. Und man braucht in dem Guide ja auch die ifo files, welche ich ja bei einer SVCD Source nicht vorhanden sind. Wie soll ich das dann mit diesem Guide machen? Wenn Du ein anderes Guide kennst, was mein Problem lösen könnte, hätte ich es gern!

wie schon rasta21 geschrieben hat, ist es egal welche Source Du nimmt, ob VOB, SVCD oder VCD. In dem Guide wird ja auch beschrieben, wie ein paar Ausschnitte für Dein Menü nimmst und es in MPEG2 wandelst.

Hast Du schon mal DVD2SVCD oder AVI2SVCD/DVD manuell gewandelt ?
Dein SVCDMPEG material kannst Du auch mit Deinem VideoEditor "füttern".

Ich mache es anders, wenn es schnell gehn soll. mein Altes Beispiel fürs geb :

Zitat

video_max_width=640
video_max_height=480
video_max_border = 48
# lehres Video erzeugen
BlankClip(length=200,width=video_max_width,height=video_max_height,fps=25,color=$000000).ConvertToRGB32
# Sourcen Video Laden + Schneiden
video = mpeg2source("Pin_Ups_Menu.d2v").Crop(15,87,695,407)
# maximal Breite von Sourcen Video berechnen
resw = (video_max_width - (video_max_border * 3)) / 2
# maximal Höhe von Sourcen Video berechnen
resh = (Height(video) * resw) / Width(video)
# maximal Höhe von Sourcen Video setzen + in RGB32 schalten
video = video.BilinearResize(resw,resh).ConvertToRGB32
# maximal Höhe der Maske setzen + in RGB32 schalten
maske = AVISource("vpack.avi",false).BicubicResize(resw,resh).ConvertToRGB32.Loop()
# Top von den Summe der CHAPTERS.Video berechnen
restop= (video_max_height - ((video_max_border *3) + (resh *2))) / 2
# CHAPTERS setzen und Sourcen Video mit Maske verbinden + Tasten Nummer
v1=Layer(video,maske,"mul",255).Subtitle("1",20,20,0,200,"Arial",32,$FFFFFF,$000000)
v2=Layer(video.Trim(13429,0),maske,"mul",255).Subtitle("2",20,20,0,200,"Arial",32,$FFFFFF,$000000)
v3=Layer(video.Trim(28678,0),maske,"mul",255).Subtitle("3",20,20,0,200,"Arial",32,$FFFFFF,$000000)
v4=Layer(video.Trim(42393,0),maske,"mul",255).Subtitle("4",20,20,0,200,"Arial",32,$FFFFFF,$000000)
# CHAPTERS.Video mit lehres Video verbinden
Layer(last,v1,"add",255,video_max_border, restop + video_max_border)
Layer(last,v2,"add",255,(video_max_border *2) + resw,restop + video_max_border)
Layer(last,v3,"add",255,video_max_border,restop + (video_max_border *2) + resh)
Layer(last,v4,"add",255,(video_max_border *2) + resw,restop + (video_max_border *2) + resh)
#VCD 352x288
#TV-Overscan 1x
BilinearResize(344,280,0,0.75)
AddBorders(4,4,4,4)
# für TMPGEnc
ConvertToRGB24()

Alles anzeigen

[Blockierte Grafik: http://members.tripod.co.uk/BtqMbxIzvuFz/pin_ups_menu.jpg]

Wenn Du Dich überhaupt nicht auskennst, kann ich Dir gerne Weiterhelfen.

Motion-Menü per Stack-Funktion
Schritt 1: (Video Laden und Schneiden)

# mein Quell-Video ist ein DVD2AVI-Project als MPEG2,
mit einer anderen Funktion sind auch MPEG1 oder DivX als Quelle möglich (siehe Docu)
quell_video = mpeg2source("Pin_Ups_Menu.d2v")
[Blockierte Grafik: http://members.lycos.co.uk/BtqMbxIzvuFz/menu_stack01.jpg] 
# Crop(clip, int left, int top, int width, int height) < hier wird also das Video geschnitten
quell_video = Crop(quell_video,15,87,695,407)
[Blockierte Grafik: http://members.lycos.co.uk/BtqMbxIzvuFz/menu_stack02.jpg] 
# ConvertToRGB32(clip) < in RGB32 gewandelt, braucht nacher die Funktion Layer
quell_video = ConvertToRGB32(quell_video)
[Blockierte Grafik: http://members.lycos.co.uk/BtqMbxIzvuFz/menu_stack02.jpg]

Schritt 2: (Maske Laden und Anpassen)

# AVISource(string filename[,...], bool "audio", string "pixel_type") < jetzt wird ein Masken Video geladen ohne Sound
maske = AVISource("Maske_RGB24.avi",false)

# LanczosResize(clip, int target_width, int target_height) < die Maske wird auf die Größe vom Quell Video gebracht,
dazu wird per Width() und Heigth() die Größe abgefragt
maske = LanczosResize(maske,Width(quell_video),Height(quell_video))
[Blockierte Grafik: http://members.lycos.co.uk/BtqMbxIzvuFz/menu_stack03.jpg]
# ConvertToRGB32(clip)
maske = ConvertToRGB32(maske)

# Loop(clip, int "times", int "start", int "end") < da das Masken Video nur ein Frame hat, setzte ich Sie auf Unendlich
maske = Loop(maske)

Schritt 3: (Zusammenfügen von Video und Maske)

# Layer(base_clip, overlay_clip, string "op", int "level", int "x", int "y", int "threshold", bool "use_chroma")
quell_video_mit_maske = Layer(quell_video,maske,"mul",255)
[Blockierte Grafik: http://members.lycos.co.uk/BtqMbxIzvuFz/menu_stack04.jpg]

Schritt 4: (Kapitel setzen und ne Zahl für die Fernbedienung)

# Trim(clip, int first_frame, int last_frame) < Das zweite Kapitel beginnt bei Frame 13429 und wird bis zu Ende (0) gespielt. usw...
chapter1 = Trim(quell_video_mit_maske,0,0)
chapter2 = Trim(quell_video_mit_maske,13429,0)
chapter3 = Trim(quell_video_mit_maske,28678,0)
chapter4 = Trim(quell_video_mit_maske,42393,0)

# Subtitle(clip, string text, int "x", int "y", int "first_frame", int "last_frame", string "font", int "size", int "text_color", int "halo_color")
Auf die Kapitel-Videos wird ein Text gelegt
chapter1 = Subtitle(chapter1,"1",4,60,0,200,"Arial",72,$FFFFFF,$000000)
chapter2 = Subtitle(chapter2,"2",4,60,0,200,"Arial",72,$FFFFFF,$000000)
chapter3 = Subtitle(chapter3,"3",4,60,0,200,"Arial",72,$FFFFFF,$000000)
chapter4 = Subtitle(chapter4,"4",4,60,0,200,"Arial",72,$FFFFFF,$000000)
[Blockierte Grafik: http://members.lycos.co.uk/BtqMbxIzvuFz/menu_stack05.jpg]

Schritt 5: ( div. Rahmen und die Kapitel - Videos zusammenfügen)

#AddBorders(clip, int left, int top, int right, int bottom)
chapter1 = AddBorders(chapter1,20,20,20,20)
chapter2 = AddBorders(chapter2,20,20,20,20)
chapter3 = AddBorders(chapter3,20,20,20,20)
chapter4 = AddBorders(chapter4,20,20,20,20)

# StackHorizontal(clip1, clip2[,...])
chapter1_chapter2 = StackHorizontal(chapter1,chapter2)

[Blockierte Grafik: http://members.lycos.co.uk/BtqMbxIzvuFz/menu_stack06.jpg] 
chapter3_chapter4 = StackHorizontal(chapter3,chapter4)

# StackVertical(clip1, clip2[,...])
chapter1_chapter2_chapter3_chapter4 = StackVertical(chapter1_chapter2,chapter3_chapter4)

#AddBorders(clip, int left, int top, int right, int bottom)
final_video = AddBorders(chapter1_chapter2_chapter3_chapter4,80,80,80,80)
[Blockierte Grafik: http://members.lycos.co.uk/BtqMbxIzvuFz/menu_stack07.jpg]

Schritt 6: (Maximale Frames setzen und Final ?)

# Trim(clip, int first_frame, int last_frame) < das Fertige Video, wird auf 200 Frames begrenzt
final_video = Trim(final_video,0,199)

# ConvertToRGB24(clip) < braucht nur TMPGEnc
return ConvertToRGB24(final_video)

oder

return final_video

Viel Spaß beim testen / basteln

:eek: Wow!!!

Ich sag mal: Das wird 'ne Anleitung! Zumindest als Sticky. Ich hoffe nur, dass die Beispielbilder durchgehen: Wir sind ja hier kein Forum ab 18... ;D

Zitat

Originally posted by LigH
:eek: Wow!!!
Ich sag mal: Das wird 'ne Anleitung! Zumindest als Sticky. Ich hoffe nur, dass die Beispielbilder durchgehen: Wir sind ja hier kein Forum ab 18... ;D

Von sowas habe ich noch ne menge mehr, leider auch komplizierter.
Und zu AB18. Ich sehe nur Frauen und einen Ausschnitt von der FA (Seife) Werbung

Auf jeden Fall ne nette Anleitung

Cu Selur

Zitat

Originally posted by thargor
katjarella:

Ich dank Dir erstmal für die Antwort, aber wie Du schon sagtest, ich kenn mich mit sowas überhaupt nicht aus! :nein:
Von dem was Du geschrieben hast, hab ich irgendwie nur Bahnhof verstanden....
Vielleicht kannst ja daraus nen verständliches Guide für Anfänger machen?
Kannst mich auch gerne mal im ICQ ansprechen: 122348814
Gruss Thargor

Nicht soooo schlimm, als ich vor jahren das erste mal Avisynth gesehen habe. Bin ich auch fast :motz: .
Ich werde dich mal anICQ`n.

katjarella

...danke für diese super ausführliche antwort...und tschicke motive :rock:

thargor

...die ifo werden wohl nur genommen um zu wissen wo die chapters liegen. setz die chapters selber dann brauchst du die ifos nicht.

Verwendete Software
Vdub; Avisynth 2.52; Mahlprogie

_____________________

Als erstes wird unser gesammter Film mal in kleine Teile Exportiert.
mit Vdub als unkomprimiert als AVI Speichern.


# film001.avs
AviSource("Jennifer_Lopez_lets_getloud.avi")
Crop(36,36,440,312)
LanczosResize(256,184)
Trim( 2579,-600)

# film002.avs
AviSource("Jennifer_Lopez_lets_getloud.avi")
Crop(36,36,440,312)
LanczosResize(256,184)
Trim( 9241,-600)

usw...

_____________________

DVD Menü mit einem MahlProgramm erstellen und der Fantasy freien lauflassen.

Ein Screen.Shot vom Exportieren Stück
[Blockierte Grafik: http://members.tripod.co.uk/verglade8kihr/jlo_menu01.gif] 

Darüber wird eine Alphamaske gesetzt; Und ein kleiner Rahmen
[Blockierte Grafik: http://members.tripod.co.uk/verglade8kihr/jlo_menu02.gif]

Und nur die Alphamaske als Bild exportiert; ohne kleiner Rahmen
bitte Auch die Koodinaten aufschreiben.
[Blockierte Grafik: http://members.tripod.co.uk/verglade8kihr/jlo_menu03.gif]

zum schluß das gesammt DVD Menü speichern.
[Blockierte Grafik: http://members.tripod.co.uk/verglade8kihr/jlo_dvdmenu01.jpg]

_____________________

Jetzt werden das DVDMenü, die Filme und unsere Alphamasken zu einen Motion Menü zusammengefasst.


#jlo_menu01.avs

#Importieren der Filme
vOBEN = AviSource("film001.avi",false).ConvertToRGB32()
vRECHTS = AviSource("film002.avi",false).ConvertToRGB32()
vLINKS = AviSource("film003.avi",false).ConvertToRGB32()
vUNTEN = AviSource("film004.avi",false).ConvertToRGB32()

#Import des DVDMenues
dvdmenu = ImageReader("dvdmenu01.bmp",0,0,25,false).Loop(600).ConvertToRGB32()

#laden der Alphamasken
maskeOBEN = ImageReader("maskeOBEN.bmp",0,0,1,false).ConvertToRGB32()
maskeRECHTS = ImageReader("maskeRECHTS.bmp",0,0,1,false).ConvertToRGB32()
maskeLINKS = ImageReader("maskeLINKS.bmp",0,0,1,false).ConvertToRGB32()
maskeUNTEN = ImageReader("maskeUNTEN.bmp",0,0,1,false).ConvertToRGB32()

#verbinden der Filme mit den Alphamasken
vOBEN = Mask(vOBEN,maskeOBEN)
vRECHTS = Mask(vRECHTS,maskeRECHTS)
vLINKS = Mask(vLINKS,maskeLINKS)
vUNTEN = Mask(vUNTEN,maskeUNTEN)

#Filme an die Richtige Position setzen
dvdmenu = Layer(dvdmenu,vOBEN,"add",255,162,84)
dvdmenu = Layer(dvdmenu,vRECHTS,"add",255,260,178)
dvdmenu = Layer(dvdmenu,vLINKS,"add",255,64,178)
dvdmenu = Layer(dvdmenu,vUNTEN,"add",255,162,271)

return dvdmenu

_____________________

und Fertig ist unsere motion menü. Wie Ihr das nun in Euer (S)VCD/DVD einbidet, das erkläre ich nicht noch.

Motion Part 2

Hallo,
kann mir bitte jemand genau erklären wie ich die oben beschriebene Maska hinkriege. Die Maske von katjarella ist gemeint. Ist genau das, was ich seit langem suche.
Wäre schön wenn ich sowas dann in DVDLab importieren könnte.

Danke

Gruß

Alain

Zitat von AEB

Hallo,
kann mir bitte jemand genau erklären wie ich die oben beschriebene Maska hinkriege. Die Maske von katjarella ist gemeint. Ist genau das, was ich seit langem suche.
Wäre schön wenn ich sowas dann in DVDLab importieren könnte.

Hm.. das würde ich mal gerne wissen, mein Grafik Proggi kann sowas glaube ich garnicht, hab Photoimpact 6, tja und Photoshop kann ich mir nicht leisten.

Zitat von Halfzware

mein Grafik Proggi kann sowas glaube ich garnicht,

die alpha-maske in herzform kann mein Picture Publisher auch nicht. aber ich kann aus einer normalen markierung so eine maske erstellen, indem ich nach dem markieren in den alpha-kanal wechsle. dann ist der markierte bereich weiß und alles andere schwarz. wenn das auch nicht geht, mußt du die bereiche von hand füllen, das wo der clip später sichtbar sein soll (hier die herzen) muß weiß sein, bereiche die den clip verdecken sollen, werden schwarz.

Zap

hai

sagt mal wodurch lasst ihr denn den code hier laufen ?
oder wie wende ich ihn an ?

gibts da ne referenz der scriptsprache ? achja wie heißt die sprache ?

gruß
makese

:welcome:

Du meinst das AviSynth-Skript?

http://sourceforge.net/projects/avisynth2

Installer für die aktuellste Alpha besorgen (zur Zeit Version 2.5.5), installieren (dabei auch die deutsche Dokumentation auswählen), deutsche Dokumentation lesen. Sehr empfehlenswert für jeden, der kostenlos, schnell und effizient sein Videomaterial bearbeiten will.

ja hallo

!!! geile sache dat !!!

hab das natürlich gleich ausprobiert ... und hoffentlich richtig verstanden das teil ist eine serverumgebung in der man halt ne menge automatisieren kann
(zb ein script welches mir auf videos ein kleines logo einbindet)
momentan ne menge neues >>> vieleicht ein paar links ?
(referenz, auf der seite http://members.lycos.co.uk/verglade8kihr/ , )

eigentlich bin ich auf der suche nach infos über .vob und .ifo datei-editiermöglichkeiten (evt referenz) bin da auf vob und ifo edit gestoßen ... und irgendwie auf den link hier (hat gedacht das hätt was damit zu tun :nein: )

auf der seite http://members.lycos.co.uk/verglade8kihr/ steht ja auch was zum thmea dvd-erstellen mit der kommando-zeile (da wirds mir dann echt langsam unheimlich)
... ich suche eigentlich ein tool wie ifoedit (aber dann ne referenz oder so >>> ich weis da echt nicht was da was ist) mit dem man sehen kann wie sone dvd verlinkt ist und da was ändern kann (dvdlab kenne ich :ja: >>> hätte gern nur mehr kontrolle)

wie stellt man sich da am besten an ???

makese

Hallo

Wenn man ein MotionMenu mit ein Hauptmovie im Hindergrund seinen Menubild was draufliegt und darauf in einen bestimmten bereich ein zweites Video anzeigen will, kann man dort diesen Bereich so steuern das je nach Buttom ein anderes Video angezeigt wird ?

CU Ghola

Zitat von Ghola

Hallo

Wenn man ein MotionMenu mit ein Hauptmovie im Hindergrund seinen Menubild was draufliegt und darauf in einen bestimmten bereich ein zweites Video anzeigen will, kann man dort diesen Bereich so steuern das je nach Buttom ein anderes Video angezeigt wird ?

CU Ghola

Ja. In dem Du für jeden Button ein eigenes MotionMenü erstellst und diese Buttons per Autoaction und dem richtigen Menü verbindest. Wie das geht wurde glaube schon unter Authoring im Board beschrieben.

Hier noch ein kleines Beispiel, wie man aus einem Puzzle ein MotionMenu macht.

vy=100
vw=200
vh=160
vlevel=255


bgvideo =ImageReader("BG720x576.bmp",0,0,25).Loop().ConvertToRGB32()
vmask =ImageReader("puzzle%02d.bmp",0,30,1).ChangeFPS(2).Loop().ConvertToRGB32()
vmask =Trim(FreezeFrame(vmask,60,124,59),0,-124)
vmaskr =Reverse(vmask)
vmask = vmask + vmaskr


title1 =AVISource("motion1.avi",false).ConvertToRGB32()
title2 =AVISource("motion2.avi",false).ConvertToRGB32()
title3 =AVISource("motion3.avi",false).ConvertToRGB32()
title4 =AVISource("motion4.avi",false).ConvertToRGB32()
title5 =AVISource("motion5.avi",false).ConvertToRGB32()
title6 =AVISource("motion6.avi",false).ConvertToRGB32()


title1 = Mask(title1,vmask.FlipHorizontal())
title2 = Mask(title2,vmask.FlipVertical())
title3 = Mask(title3,vmask)
title4 = Mask(title4,vmask.FlipHorizontal().FlipVertical())
title5 = Mask(title5,vmask.FlipVertical().FlipVertical())
title6 = Mask(title6,vmask.FlipVertical())


title1m = LanczosResize(title1,vw,vh)
title2m = LanczosResize(title2,vw,vh)
title3m = LanczosResize(title3,vw,vh)
title4m = LanczosResize(title4,vw,vh)
title5m = LanczosResize(title5,vw,vh)
title6m = LanczosResize(title6,vw,vh)


Layer(bgvideo,title1m,"add",vlevel,40,vy)
Layer(last,title2m,"add",vlevel,260,vy)
Layer(last,title3m,"add",vlevel,480,vy)
Layer(last,title4m,"add",vlevel,40,vy + 200)
Layer(last,title5m,"add",vlevel,260,vy + 200)
Layer(last,title6m,"add",vlevel,480,vy + 200)
Trim(0,-250)

Und hier ist als FlashMovie : Maske Puzzle

Ich würde ja gerne Fragen beantworten... leider ist hier wenig loß