Convolution3d(preset="vhsBQ") Problem

"Komplett" ist das Beispiel aber noch längst nicht, wenn im Plugins-Verzeichnis keine DLLs mehr liegen: Da müssten noch jede Menge "LoadPlugin"- oder "Import"-Einträge zu finden sein - für alle Funktionen, die nicht vom AviSynth-Kern angeboten werden: Clense, Repair, RemoveGrain, TemporalRepair, LimitChange ...

hatte ich vorausgesetzt.. habs ergänzt.

Didée

Laden von SSETools.dll bringt auf meinem Athlon Thunderbird (hat meines Wissens nur SSE Integer, aber kein SSE Float) den Fehler "unrecognized exception!" (s. Anhang) bei folgendem Script:

import("d:\programme\avisynth\lib\LRemoveDust.avs")
loadplugin("d:\programme\avisynth\plugins25\ssetools.dll")
loadplugin("d:\programme\avisynth\plugins25\removegrain.dll")
loadplugin("d:\programme\avisynth\plugins25\repair.dll")


avisource("capture.avi",true,"YUY2")


converttoyv12()
LRemoveDust(4,1)

Somit steht mir LimitChange nicht zur Verfügung. Angeblich gibts ja auch eine Version von LRemoveDust ohne LimitChange. Ist die genauso gut und kannst du diese evtl. posten?

Danke dir!

Warum ist das verwirrend? Überleg doch mal:

a) Du läßt die Deklaration weg: Wie soll AviSynth dann die Funktion ausführen, wenn es nicht weiß, was darin ablaufen soll?

b) Du läßt den Aufruf weg: Dann wird die Funktion ja nie angewendet.

Nein, es muss schon beides vorhanden sein: Erst muss AviSynth die Funktion kennenlernen, und dann auch noch anwenden.
__

Wenn ich jetzt auch noch davon anfange, dass AviSynth ein Skript eigentlich "von hinten" liest, also im Skript eigentlich erst die Anwendung und dann erst die Deklaration verwendet werden könnte... -- Nee, lass mal so, wie's funktioniert.

Didée

Die Version ohne SSETools bzw. LimitChange müsste dann diese hier sein, richtig?

function LRemoveDust(clip input, int _mode, int "limit")
{
limit=default(limit,4)
LL=string(limit)
STR="x "+LL+" + y < y "+LL+" - x "+LL+" - y > y "+LL+" + x ? ?"
repmode = 2
clensed = Clense(input)
rep=Repair(clensed, input, mode=repmode)
rg = RemoveGrain(rep, mode=_mode)
TemporalRepair(rg, rep)
return limit!=0 ? yv12lutxy(last,input,yexpr=STR,U=2,V=2) : last
}

Zumindest läuft diese hier auch auf meinem Athlon T-Bird einwandfrei!

Gehe ich recht in der Annahme, dass der Wechsel von YV12lutxy (MaskTools) auf LimitChange (SSETools) keinen qualitativen, sondern nur einen Geschwindigkeitsvorteil bringt?

@ acrowley:

Jo, ist ein recht flottes Filterchen, nicht wahr?

kassandro hat sogar von Extremfällen berichtet, in denen das XviD-Encoding mit RemoveDust() um 20%-25% schneller war als direktes Encoding ganz ohne Filterung!

Wie kann das sein? Im gegebenen Fall hatte die Quelle *sehr* starke Körnung -- durch die [sehr schnelle] Verminderung des Rauschens wurde für XviD die Bewegungssuche während des Encodings viel einfacher, und deswegen lief der Prozess mit Filterung schneller als ohne. Allerdings war das RemoveDust, nicht LRemoveDust.

Betreffs ModerateSharpen: Da sollte man schwächere Werte für den Sharpen()-Befehl verwenden, je nach Quelle 0.2 bis 0.6. Sharpen(1) ist vieeel zu viel, ohne Supersampling.

Wenn's richtig gut werden soll, geht meine Empfehlung natürlich zu LimitedSharpen. Zwar deutlich langsamer, aber auch deutlich "besser".

@ grua

Antwort auf alle Fragen: Ja.

Das ist die Version, und die Quali ist genau die gleiche, nur einen Tick langsamer. Hab' noch nie verglichen, wie groß der Unterschied LimitChange()<--> yv12lutxy() in der Praxis wirklich ist. Aber so sehr viel kann das eigentlich nicht ausmachen.

Allerdings ist das die "Limiting-nur-für-Luma"-Version. Der Vollständigkeit halber kommt nachfolgend eine "vollständige" Version, mit mehr Möglichkeiten für's Chroma-Processing (mit yv12lutxy statt LimitChange):

LRemoveDust( _mode, [limit], [limitC] )

"_mode" und "limit" machen das gleiche wie bisher auch (logisch)

limitC = ...

... [1,255] - beschränkt Chroma-Änderungen auf maximal diesen Wert.

... [0] -- kein Limiting für Chroma (schneller)

... [-1] -- Chroma? Was ist das? (Noch schneller, für B/W-Clips. Hinterher manuell Greyscale() anwenden!)

... [-255,-2] - die U/V-Ebenen werden mit diesem Wert gefüllt.

function LRemoveDust(clip input, int _mode, int "limit", int "limitC")
{
limit  = default(limit, 4)
limitC = default(limitC,0)      #  default chroma limit: no chroma limiting!
#limitC = default(limitC,limit) #  alternative: default chroma limit = luma limit
LLy    = string(limit)
LLc    = string(limitC)
STRy   = "x "+LLy+" + y < y "+LLy+" - x "+LLy+" - y > y "+LLy+" + x ? ?"
STRc   = "x "+LLc+" + y < y "+LLc+" - x "+LLc+" - y > y "+LLc+" + x ? ?"
uv = (limitC < -1) ?  limitC
 \ : (limitC <  0) ?  1
 \ : (limitC <  1) ?  2 
 \ :                  3


repmode   = 2
repmodeUV = (uv > 1) ? repmode : -1
_modeUV   = (uv > 1) ? _mode   : -1


clensed = Clense(input)
rep     = Repair(clensed, input, mode=repmode, modeU=repmodeUV)
rg      = RemoveGrain(rep, mode=_mode, modeU=_modeUV)
TemporalRepair(rg, rep)
yv12lutxy(last, input, STRy, STRc, STRc, U=uv, V=uv)
return last
}

Danke, Didée!