hilfe: Bildqualität eines digitalisierten Video 8 Schmalfilms retten

Hallo saibo,

ich bin auch gerade mit der Materie zugange, bin aber noch dabei, das Abfilmen zu verbessern (Synchronisierung zw. Projektor und Videokamera).

Bei den Filtern bin ich zur Zeit bei TBilateral angelangt, ein rein spatialer (intraframe) Filter; von temporalen Filtern würde ich abraten, weil man fast nie einen exakten Bildstand hat, d.h. das Bild ruckelt meist leicht sowohl vertikal als auch horizontal; das würde bei einem temporalen Filter zu unnötigen Unschärfen und Artefakten führen.

Vielleicht hat ja sonst noch jemand hier Erfahrungen ...

Gruß Georg

Ich hab mir das Zeug von Saibo mal angeguckt, aber da sind meine Erfahrungen mit Denoisen, Deblocken, und clever Nachschärfen einfach nicht ausreichend. Ich krieg da nix schöneres raus, entweder ich verliere zuviele Details oder man sieht den Effekt gar nicht.

Cu Selur

So richtig "schön" wird das wohl auch nicht werden. Zu wenig Detail, und von zu viel Artefakten überlagert. Hab die Samples einfach mal auf'm (Röhren-) TV abgespielt, und sooo schlimm hat das dort gar nicht ausgesehen. Ob es sich am Ende lohnt, da großen Aufwand zu betreiben, nur damit es anders aussieht ...

Mit temporalen Filtern hab' ich (noch) gar nicht erst angefangen. Unter vorübergehender Missachtung, das die Quelle vor der Bearbeitung erst mal noch auf die zugrundeliegenden 18fps progressiv zurückgebracht (und danach für DVD wieder re-gepulldowned) werden muss , hab ich mal mit ein wenig spatialer Basis-Filterung etwas gegen Block- und sonstige Artefakte versucht.

Test1 Frame 525, vorher - nachher:

[Blockierte Grafik: http://img150.imageshack.us/img150/4374/t1fr525origtr6.th.png] [Blockierte Grafik: http://img242.imageshack.us/img242/79/t1fr525ppru3.th.png]

Test2 Frame 25, vorher - nachher:

[Blockierte Grafik: http://img242.imageshack.us/img242/651/t2fr25origui5.th.png] [Blockierte Grafik: http://img97.imageshack.us/img97/1530/t2fr25ppxo4.th.png]

Die enthaltene Schärfung ist ziemlich zurückhaltend, um "den Look" des Ergebnisses recht nahe am Original zu halten. Ein richtiges "Aufmotzen" mit Schärfefiltern wird hier höchstwahrscheinlich nicht schön werden, sondern wird sehr schnell ins Lächerliche abgleiten.

400% Zoom, vorher - nachher:

[Blockierte Grafik: http://img89.imageshack.us/img89/2371/t2fr25zoomorigar7.th.png] [Blockierte Grafik: http://img80.imageshack.us/img80/9311/t2fr25zoomppjm1.th.png]

Also, "anders" isses damit schon mal. Aber ob das nun auch "besser" ist ... ist Ansichtssache.

Verwendet wurden übrigens Deblock_QED, RemoveGrain/Repair + Unscharfe Maskierung + MaskTools, EEDI2 und etwas LimitedSharpen ... also ausschließlich Basis-Filter.

Didée: Wie sieht den das Script aus was Du benutzt hast?
Die Artefakte sind wirklich 'schön' zurück gegangen bei Dir.

Cu Selur

Tjaaa, das Script ist auf dem USB-Stick, den ich dort vergessen habe, wo ich erst am Mittwoch wieder hinkomme ...

Genau krieg' ich das jetzt auch nicht mehr zusammen. Jedenfalls benutzt das Script "Konterschärfung", wobei nach dem Smoothen angewendete Kontrast-/Schärfungs-Filter durch die Differenz (Smooth - Original) limitiert werden. Das funktioniert in vielen Fällen sehr gut.

Angefangen hab' ich mit

Doubleweave().TFM().TDecimate(mode=7,rate=18.0)

um 18fps progressiv herzustellen. Dann ging's weiter mit

Merge(Removegrain(3),0.49)
Deblock_QED(quant1=36,quant2=36,aOff1=2,bOff1=4,aOff2=4,bOff2=8)

und weg sind die Blöcke. Die Linien-im-Block-Artefakte vom interlacten Encoding, die trotz RemoveGrain(3) noch übriggeblieben sind, hat dann das Funktiönchen Vinverse() weggemacht (die aber noch kaum keiner kennt), weiss aber nicht mehr, ob vor oder nach dem Deblocking. Wahrscheinlich eher hinterher.
Anschließend verbogen Unscharf Maskiert, und den Effekt der vUSM gemäß der Differenz des aktuellen Standes zum Input begrenzt. Eingebettet in diese vUSM-Sequenz LimitedSharpen angewendet. Am Ende per EEDI2 resampled.

Das müsste so im Groben alles gewesen sein. Hört sich schlimmer an als es ist ... die Speed wird dabei hauptsächlich durch EEDI2 heruntergedrückt, der Rest geht eigentlich.

Werde mir das Skript dann mal nächste Woche angucken, wenn due s Mittwoch potest, da ich Mittwoch bis Sonntag wohl offline bin, hört sich aber nicht schlecht an.

Cu Selur

Problem: der Stick ist verschwunden. Fast ein GB an Daten, die ich noch gebraucht hätte. Suche jetzt ein sehr hohes Gebäude, zum Springen.

Stick hat sich wieder eingefunden. ( "Schorsch! Mei Tropfe!" )

LoadPlugin("RemoveGrain.dll")
LoadPlugin("repair.dll")
LoadPlugin("mt_masktools.dll")


Import("LimitedSharpenFaster.avs")
#Import("vinverse.avs")


AviSource("test2_saibo.avi")
o=last
ox=o.width()
oy=o.height()


o.separatefields().pointresize(ox,oy)
o2=last


merge(removegrain(4),0.49)
deblock_qed(quant1=36,aOff1=4,bOff1=4,quant2=40,aOff2=4,bOff2=8)
vinverse(1.60) .clense()


clean = mergeluma(removegrain(4),0.49)
cleanD= mt_makediff(clean,o2,U=3,V=3)
USMD  = mt_makediff( clean.bicubicresize(m4(ox/3.0),m4(oy/3.0)).bicubicresize(ox,oy,1,0),
 \                   clean.merge(clean.removegrain(4,0),0.49), U=3,V=3)
USMDD = USMD.repair(cleanD,1,3)


clean.mt_makediff(USMDD.removegrain(11,0),U=3,V=3)
eedi2().mt_convolution("1","0 -3 8 8 -3",U=3,V=3).turnleft()
eedi2().mt_convolution("1","0 -3 8 8 -3",U=3,V=3).turnright().bicubicresize(ox,oy,0.2,0.4)
limitedsharpenfaster(ss_x=1.414,ss_y=1.414,strength=160,soft=66,overshoot=2)


blurr = bicubicresize(m4(ox/4.0),m4(oy/4.0)).bicubicresize(ox,oy,1,0)
p1    = mt_lutxy(last,blurr,expr="x y - abs 4 < x x x y - abs 3 - 0.32 * x y - x y - abs 0.0001 + / * - ?",U=2,V=2)
removegrain(11,-1)
mt_makediff(removegrain(4,-1))


p1.mt_adddiff(last,U=2,V=2)#.mt_adddiff(xD.removegrain(11),U=2,V=2)


# re-weave 50p zu 25i für DVD
assumeframebased().separatefields().selectevery(4,0,3).weave()


return(last)


#-----------


function m4(float x) {x<16?16:int(round(x/4.0)*4)}


function Vinverse(clip clp, float "str", int "amnt", int "uv") 
{
str  = default( str, 2.6 )
uv   = default( uv,    3 )
amnt = default( amnt, 255)
SSTR = string(str)
AMT  = string(amnt)
vblur  = clp.mt_convolution("1","1 2 1",U=uv,V=uv)
vblurD = mt_makediff(clp,vblur,u=uv,v=uv)
Vshrp  = mt_lutxy(vblur,vblur.mt_convolution("1","1 4 6 4 1",U=uv,V=uv),"x x y - "+SSTR+" * +",U=uv,V=uv)
VshrpD = mt_makediff(Vshrp,vblur,u=uv,v=uv)
Vhalu  = mt_lutxy(VshrpD,VblurD,"x 128 - abs y 128 - abs < x y ?",u=uv,v=uv)
mt_adddiff(Vblur,Vhalu,U=uv,V=uv)
(amnt>254) ? last : mt_lutxy(clp,last,"x "+AMT+" + y < x "+AMT+" + x "+AMT+" - y > x "+AMT+" - y ? ?",U=uv,V=uv)
}

Ach so ... ffdshow hat mir das bereits in YV12 dekodiert, sorry.

>> o.separatefields().pointresize(ox,oy)
>> ConvertToYV12()
>> o2=last

Ausserdem muss am Anfang auch noch

>> Import("deblock_qed.avs")

stehen. Ohne dieses Script geht nix, das ist ja eigentlich der zentrale Part, um den alles andere herumtanzt.

Du hast nicht den notwendigen VfW DV Codec installiert..
"dvsd" wurde imho von Pinnacle bei der DV300 verwendet.
In ffdshow in der VfW Konfiguration auf libavcodec setzen.

Das Installieren von ffdshow alleine reicht wahrscheinlich nicht.

Man muss es auch konfigurieren.

Wie du sicherlich beim Suchen nach Stichworten wie "locate decompressor dvsd" in Google oder hier im Forum herausgefunden hast, benötigst du einen VfW-Codec für das DV-Videoformat. Das kann man in der VfW-Konfiguration von ffdshow im Decoder-Bereich bei "Codecs" aktivieren, indem man den Eintrag für DV auf "libavcodec" stellt.