Dank FAUST, nutze ich für Hybrid ja seit geraumer Zeit (unicode) NSIS mit folgendem Skript:
Code
;,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,
;
; Hybrid NSIS installer script by FAUST
;
; This Script uses follwoing features:
;
; - get the Version string of the Main Application Executabel (-> DL @ NSIS HP -> http://nsis.sourceforge.net/Invoking_NSIS_run-time_commands_on_compile-time)
; - OS diference of x64 and Windows2000 (-> x64.nsh & WinVer.nsh -> included in NSIS)
; - Aero Plug-in by AfrowUK (-> Aero.dll -> DL @ NSIS HP)
; - Win7 Progressbar Plugin by AfrowUK (-> w7tbp.dll -> DL @ NSIS HP)
;
;
;
;
;
;,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,
;-----
; # Use the Modern Skin:
!include "MUI.nsh"
; # for x64 detection:
!include x64.nsh
; # for the Windows Version detection:
!include WinVer.nsh
; # define the user plugin directory:
!addplugindir ..\plugins
; # AERO Plug-in initialisation line
!define MUI_CUSTOMFUNCTION_GUIINIT onGUIInit
; # to use the "locate" funtion for the reset/deletion section
!include "FileFunc.nsh"
; # for .ini line editing
!include "WordFunc.nsh"
; # optional custom page choice
!include "logiclib.nsh"
!include "sections.nsh"
;!include InstallOptions.nsh
;-----------------------------
;-----------------------------
;
; misc settings
;
; - compression level, OutFile, etc.
;-----------------------------
# max compression settings
SetCompressor /SOLID lzma
SetDatablockOptimize on
SetCompressorDictSize 120
; die DictSize sollte groesser sein als das unkomprimierte archiv insgesamt
; Aber NICHT grösser als 149 !!!
; Wenn der compiler mit dieser Meldung ended, dann muss die Dict Size kleiner eingestellt werden:
; ->> Packed 1 file.
; ->> Generating uninstaller... Internal compiler error #12345: deflateInit() failed(initialization failed [-2]).
; ->>
; ->> Note: you may have one or two (large) stale temporary file(s)
; ->> left in your temporary directory (Generally this only happens on Windows 9x).
;
; ; # set "setcompress off" for testing purposes only +++> deactivate upper 3 compression Options!
; SetCompress off
; # for the custom info page, initials
; # ReserveFile "${NSISDIR}\Plugins\InstallOptions.dll"
ReserveFile "..\plugins\_custompage-explain_links.ini"
; # Target Windows XP as minimal OS
; # TargetMinimalOS 5.1
;-----
;----------------
;----------------
; INITIALS
;
; - do things before the compiler creates the installer:
;----------------
Function .onInit
; # GET the "FILE VERSION" FROM "HYBRID.EXE" and define it as "${VERSION}" for later usage in the installer
; from -> http://nsis.sourceforge.net/Invoking_NSIS_run-time_commands_on_compile-time
!system "..\plugins\GetVersion-from-hybrid32\GetVersion-from-hybrid32.exe"
!include "..\plugins\GetVersion-from-hybrid32\Version.txt"
!include "..\plugins\Product.txt"
; # cut from the 2. right position for the title name for -> Caption "Hybrid - ${VERSION2}"
StrCpy $1 "${VERSION}" -2
!define VERSION2 "$1"
; # initialize the InfoPage
!insertmacro MUI_INSTALLOPTIONS_EXTRACT_AS "..\plugins\_custompage-explain_links.ini" "InfoPage"
InitPluginsDir
File /oname=$PLUGINSDIR\_custompage-INI-DIR.ini "..\plugins\_custompage-INI-DIR.ini"
FunctionEnd
; # (This function is called later in script -> onGUIInit)
; # Q: ALREADY EXIST INSTALLATION? -> if yes, quit? or go on with the installation?
Function alreadyexistcheckfunktion
; # check RegKey existence
ReadRegStr $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Hybrid" "InstallPath"
IfErrors jumpout ""
ReadRegDWORD $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Hybrid" "InstallPath"
MessageBox MB_ICONQUESTION|MB_YESNO "Looks like Hybrid is already installed in:$\r$\n$\r$\n$0$\r$\n$\r$\nDo you want to continue the installation anyway$\r$\nand update Hybrid?" IDYES jumpout
; # aborting and EXIT
MessageBox MB_ICONINFORMATION|MB_OK "Stopping installation process"
Abort
;---------EOS
jumpout:
FunctionEnd
; # Break the installation when OS is older then WinXP+SP2
Function startcheckunsupportedOS
${If} ${IsWinXP}
${AndIf} ${AtMostServicePack} 1
${OrIf} ${AtMostWin2000}
MessageBox MB_ICONINFORMATION|MB_OK "Hybrid only supports Windows XP (SP2) and newer versions of Windows!$\r$\n$\r$\nStopping installation process..."
Abort
${EndIf}
FunctionEnd
; # Function needed for the deletion of the hybrid defaults (-> "HybridMain" Section)
Function LocateCallback
Delete $R9
Push $0
FunctionEnd
; # Create the XML file for the mplayer Fonts setting
Function fontxmlcreate
FileOpen $R0 "$INSTDIR\fonts\local.conf" w
GetFullPathName /SHORT $1 $APPDATA
FileWriteUTF16LE $R0 '<!DOCTYPE fontconfig SYSTEM "fonts.dtd">$\n<fontconfig>$\n$\t<dir>$1\hybrid\fonts</dir>$\n$\t<cachedir>$1\hybrid\fontconfig\cache</cachedir>$\n</fontconfig>'
FileClose $R0
FunctionEnd
;-------------------------
;
; # INPUT DIRECTORYS
;
; Copy the binary into these directorys
!define BIN "..\_Hybrid_current-build_files-32"
!define BIN64 "..\_Hybrid_current-build_files-64"
!define BINaviext "..\_Hybrid_current-build_files-aviext"
;,,,,,,,,,,,,,,,,,,,,,,,,,,,,,
;--------------
; # Name of the compiled installer.exe
OutFile "Hybrid_${VERSION}_SETUP.exe"
; # always overwrite files in destination directory
SetOverwrite on
;--------------
; # standard target install directory: (will also work on 32bit OS !)
InstallDir $PROGRAMFILES64\Hybrid
; -> look for an previously installation and use its path if detected
InstallDirRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Hybrid" "InstallPath"
;--------------
; # Main program name:
Name "Hybrid"
; # The installer window title:
Caption "Hybrid - ${VERSION2}"
; # "Gray text" title
BrandingText "Hybrid installation setup"
; # this does somethink important.. i guess...
CRCCheck on
; # Use upx-runtime-compressor on the installer header to shrink the size. (for a couple of kb...)
; !packhdr header.dat "..\plugins\upx.exe --best header.dat"
;
; # Win7 taskbar progressbar plugin. (This Plug-in activates the Taskbar as progressbar under Windows 7)
Function createInstFiles
w7tbp::Start
FunctionEnd
; # for the ini choice
Var UserIniPath
; Var DefaultIniDirectory
Var DefaultIniDirectoryEscaped
; Var MiscIniDirectoryUnEscaped
Var UserIniPathEscaped
;,,,,,,,,,,,,,,,,,,,,,,,,,,,,,
;-----------------------------
;-----------------------------
;
; GENERAL SETTINGS
;
; - TITLE, TEXT & BUTTONS on PAGES
;-----------------------------
;
; # START PAGE text
!define MUI_WELCOMEPAGE_TITLE "Hybrid ${VERSION2} - Setup Wizard"
!define MUI_WELCOMEPAGE_TITLE_3LINES
!define MUI_WELCOMEPAGE_TEXT "This wizard will guide you through the installation of Hybrid.\r\n\r\nIf you have previously installed Hybrid and it is currently running, please exit Hybrid first before continuing this installation.\r\n\r\n$_CLICK"
;-----
; # COMPONENTS PAGE
!define MUI_COMPONENTSPAGE_TEXT_TOP "Check the components you want to install and uncheck the components you don't want to install. The setup will install the right binarys for your OS. Click Next to continue."
;-----
; # INSTALL PAGE options
ShowInstDetails show
; !define MUI_FINISHPAGE_NOAUTOCLOSE ; # deaktiviert das automatische schließen des InstallerPage Fenster
;-----
; # FINISH PAGE text / options
!define MUI_FINISHPAGE_TITLE_3LINES
; !define MUI_FINISHPAGE_TEXT "Hybrid has been installed on your computer.\r\n\r\n\r\nDon't forget to copy the neroAacEnc.exe to the Hybrid program directory !\r\n\r\n\r\nClick Finish to close this wizard"
!define MUI_FINISHPAGE_TEXT_LARGE
; # Run EXE ?
!define MUI_FINISHPAGE_RUN "$INSTDIR\Hybrid.exe"
!define MUI_FINISHPAGE_RUN_NOTCHECKED
; # WebPage
!define MUI_FINISHPAGE_LINK "Visit the Hybrid website for the latest news"
!define MUI_FINISHPAGE_LINK_LOCATION "http://www.selur.de/"
;-----
; # surface options / GFX
!define MUI_WELCOMEFINISHPAGE_BITMAP "..\gfx\Hybrid-Welcome.bmp"
!define MUI_UNWELCOMEFINISHPAGE_BITMAP "..\gfx\orange-uninstall.bmp"
!define MUI_COMPONENTSPAGE_CHECKBITMAP "..\gfx\simple-round.bmp"
!define MUI_COMPONENTSPAGE_SMALLDESC
!define MUI_ABORTWARNING
!define MUI_UNABORTWARNING
!define MUI_ICON "..\gfx\hybrid-install-icon3.ico"
!define MUI_UNICON "..\gfx\orange-uninstall.ico"
!define MUI_HEADERIMAGE
!define MUI_HEADERIMAGE_RIGHT
!define MUI_HEADERIMAGE_BITMAP "..\gfx\Hybrid-Logo-Header.bmp"
!define MUI_HEADERIMAGE_UNBITMAP "..\gfx\Hybrid-Logo-Header.bmp"
;-----------------------------------
; # Installer.exe file settings
VIAddVersionKey "ProductName" "Hybrid"
; VIAddVersionKey "Comments" "DL newest version @ www.selur.de"
; VIAddVersionKey "CompanyName" "no company"
VIAddVersionKey "LegalCopyright" "Hybrid.exe is © by Selur"
VIAddVersionKey "FileDescription" "Setup for the Hybrid Package"
VIAddVersionKey "ProductVersion" "${ProductV}" ; # predefined. something like-> !define ProductV "c000"
VIAddVersionKey "FileVersion" "${VERSION}"
VIProductVersion "${VERSION}"
;-----------------------------------
; # insert pages
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_LICENSE "License2.rtf"
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_DIRECTORY
; !insertmacro MUI_PAGE_INSTFILES
; # Custom page for ini selection. Only appears when option is selected on the components page
Page Custom CustomUserIniPage
Page instfiles "" createInstFiles ; # instead of the standard-installpage ("MUI_PAGE_INSTFILES"). for the Windows taskbar progressbar plugin
Page Custom CustomInfoPage
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_UNPAGE_WELCOME
!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES
!insertmacro MUI_UNPAGE_FINISH
!insertmacro MUI_LANGUAGE "English"
;,,,,,,,,,,,,,,,,,,,,,,,,,,,,,
;-----------------------------
;-----------------------------
;
; onGUIInit Functions
;
;-----------------------------
Function onGUIInit
; # Break the installation when OS is older then WinXP+SP2
CALL startcheckunsupportedOS
; # Aero window plugin activation - have to be activated later in the script
Aero::Apply [Options]
; # on installer start: look for an previously installed version:
CALL alreadyexistcheckfunktion
FunctionEnd
;,,,,,,,,,,,,,,,,,,,,,,,,,,,,,
;-----------------------------
;-----------------------------
;
; Installer Page Sections
;
; - Options showed at the section page:
;-----------------------------
SubSection "!Hybrid" HybridMain
;## ALL MAIN INSTALLATION PROCEDURES IN THIS SECTION
Section "Main Files" hybrid32
; # -> RO : read only : forced=ON
SectionIn RO
SetOutPath $INSTDIR
; Delete license.txt if it contains 1 of these lines...
Push 1 ;line number to read from
Push "$INSTDIR\avisynthPlugins\license.txt" ;text file to read
Call ReadFileLine
Pop $0 ;output string (read from file.txt)
;MessageBox mb_ok $0
${If} $0 = "9f0a2b12001bf7424c692b0d05e21a62b0661d42d7813d8c8ba65ba548852545"
; MessageBox mb_ok if1
Delete "$INSTDIR\avisynthPlugins\license.txt"
${EndIf}
${If} $0 = "546b27acf3bd962b68200ecad1b5137e34ce790a129de7606c7b5773aae99b6e"
; MessageBox mb_ok if2
Delete "$INSTDIR\avisynthPlugins\license.txt"
${EndIf}
File /r "${BIN}\*"
; # if OS=x64 then copy binarys from BIN64 direcory
${If} ${RunningX64}
File /r "${BIN64}\*.*"
${EndIf}
; # Always copy 32bit avsInfo.exe and avsViewer into installdir, overwriting the 64bit files
File "${BIN}\avsInfo.exe"
File "${BIN}\avsViewer.exe"
; # delete always Hybrid´s "ModelDefaults" during the installation in "%appdata%/hybrid"
IfFileExists "$APPDATA\hybrid" "" "+2"
${Locate} "$APPDATA\hybrid" "/L=F /M=* Hybrid Default.xml" "LocateCallback"
; # Create the XML file for the mplayer Fonts setting
IfFileExists "$INSTDIR\fonts\local.conf" 0 +2
Delete "$INSTDIR\fonts\local.conf"
Call fontxmlcreate
SectionEnd
SubSectionEnd
SubSection "Shortcuts" Shortcuts
; # Startmenü entrys
Section "Start Menu" StartMenu
SetOutPath $INSTDIR
SetShellVarContext current
CreateDirectory "$SMPROGRAMS\Hybrid"
CreateShortCut "$SMPROGRAMS\Hybrid\Hybrid.lnk" "$INSTDIR\Hybrid.exe"
CreateShortCut "$SMPROGRAMS\Hybrid\Uninstall.lnk" "$INSTDIR\Uninstall.exe"
SectionEnd
; # Desktop Icon
Section "Desktop" Desktop
SetShellVarContext current
SetOutPath $INSTDIR
CreateShortCut "$DESKTOP\Hybrid.lnk" "$INSTDIR\Hybrid.exe"
SectionEnd
SubSectionEnd
SubSection /e "Options" Options
; # reset Hybrid defaults settings on start of the installation?
; (this will just delete the config files on the default directory)
Section "Avisynth Extension" avisynthext
SetShellVarContext current
File /r "${BINaviext}\*"
SectionEnd
Section /o "Reset Defaults" delDef
SetShellVarContext current
IfFileExists "$APPDATA\hybrid\*ModelDefaults.xml" "" "notdeleteonsection"
Delete "$APPDATA\hybrid\*ModelDefaults.xml"
notdeleteonsection:
SectionEnd
;,,,,,,,,,,,,,,,,,,,,,,,,,,,,,
; ; MessageBox MB_OK "misc $MiscIniDirectoryUnEscaped"
;-----------------------------
;-----------------------------
;
; CUSTOM PAGE - misc.INI
;
; - this Custom page will ask for a User defined Settings path
;-----------------------------
Section /o "User defined settings path" UserIniChoice
SectionEnd
SubSection "Advanced 64bit OS Options" 64bitosoptions
; # aditional avsinfo/avsViewer option
Section /o "Use 64bit Avisynth, this will not work with the avisynth extension" avsInfo ; this will disable the avisynth extension
SetOutPath $INSTDIR
${If} ${SectionIsSelected} ${avisynthext}
; MessageBox MB_OK avisynthext1
goto jumpavsInfo
${Else}
; MessageBox MB_OK avisynthextelse2
${If} ${RunningX64}
File "${BIN64}\avsInfo.exe"
File "${BIN64}\avsViewer.exe"
; # remove avisynthPlugins folder, since it is for Avisynth 32bit only!
RMDir "$SMPROGRAMS\Hybrid\avisynthPlugins"
; MessageBox MB_OK avisynthextelse3
${EndIf}
${EndIf}
jumpavsInfo:
SectionEnd
; # aditional ffmpeg.exe option
Section /o "Use 32bit ffmpeg.exe" ffmpeg
SetOutPath $INSTDIR
${If} ${RunningX64}
File "${BIN}\ffmpeg.exe"
${EndIf}
SectionEnd
SubSectionEnd
SubSectionEnd
Function ReadFileLine
Exch $0 ;file
Exch
Exch $1 ;line number
Push $2
Push $3
FileOpen $2 $0 r
StrCpy $3 0
Loop:
IntOp $3 $3 + 1
ClearErrors
FileRead $2 $0
IfErrors +2
StrCmp $3 $1 0 loop
FileClose $2
Pop $3
Pop $2
Pop $1
Exch $0
FunctionEnd
Function CustomInfoPage
; ; # for the custom info page, install directory replacement
InitPluginsDir
File /oname=$PLUGINSDIR\_custompage-explain_links.ini "..\plugins\_custompage-explain_links.ini"
; WriteIniStr $PLUGINSDIR\_custompage-explain_links.ini "Field 6" "State" '"$INSTDIR"'
; # Headlines
!insertmacro MUI_HEADER_TEXT "Further Installation Information" " "
; # show the Page
;#version1
; !insertmacro MUI_INSTALLOPTIONS_DISPLAY "InfoPage"
;#version2
InstallOptions::dialog "$PLUGINSDIR\_custompage-explain_links.ini"
FunctionEnd
Function CustomUserIniPage
${IfNot} ${SectionIsSelected} ${UserIniChoice}
Abort
${EndIf}
#--------------------
; define default settings dir, in dependency of the user system path
!define DefaultIniDirectory "$APPDATA\hybrid"
; create an escaped version of that path
${WordReplace} "${DefaultIniDirectory}" "\" "\\" "+" $DefaultIniDirectoryEscaped
; write CustomPage .ini with path from MISC.ini <IF EXIST
WriteINIStr "$PLUGINSDIR\_custompage-INI-DIR.ini" "Field 2" "state" ${DefaultIniDirectory}
; write CustomPage .ini with updated %APPDATA%\hybrid
WriteINIStr "$PLUGINSDIR\_custompage-INI-DIR.ini" "Field 3" "text" `Please choose a path for the settings files.\r\nIf you don´t know what that means, just leave the path to the default path: "%APPDATA%\hybrid"\r\n\r\nOn your machine the default path is:\r\n"${DefaultIniDirectory}"`
; # Headlines
!insertmacro MUI_HEADER_TEXT "Optional Path Setting" "Please define a path"
; # show the custom page dialog
Push $R0
InstallOptions::dialog $PLUGINSDIR\_custompage-INI-DIR.ini
Pop $R0
; get the user dialog string
ReadINIStr $UserIniPath "$PLUGINSDIR\_custompage-INI-DIR.ini" "Field 2" "state"
; escape the path from the input
${WordReplace} "$UserIniPath" "\" "\\" "+" $UserIniPathEscaped
WriteINIStr "$INSTDIR\misc.ini" General settingPath $UserIniPathEscaped
Pop $R0
FunctionEnd
;,,,,,,,,,,,,,,,,,,,,,,,,,,,,,
;-----------------------------
;-----------------------------
;
; uninstall tasks
;
; - things to do at the execution of the uninstall.exe
;-----------------------------
Section "Uninstall"
SetShellVarContext all
; # Check validity of the $INSTDIR variable. Compares the uninstall.exe location with the RegKey value.
ClearErrors
ReadRegStr $2 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Hybrid" "InstallPath"
IfErrors 0 +2
ReadRegStr $2 HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\Hybrid" "InstallPath"
${If} $2 != $INSTDIR
; # Something is wrong! Fall back to checking for filenames.
${IfNot} ${FileExists} "$INSTDIR\Hybrid.exe"
MessageBox MB_OKCANCEL|MB_ICONEXCLAMATION "WARNING: Setup could not verify that this uninstaller is being run from its proper \
directory. If you have moved Uninstall.exe to a directory other than the actual installation folder, it is \
impossible to guarantee that the uninstallation will be executed properly. If you proceed, it is theoretically \
possible that setup will delete files that should not be deleted. Are you sure you wish to continue with \
the uninstallation?$\r$\r-OK to continue and uninstall the application from:$\r$\n '$2' $\r$\n-CANCEL to end" IDOK +2
quit ; # quit installer.
${EndIf}
${EndIf}
Delete "$DESKTOP\Hybrid.lnk"
Delete "$INSTDIR\Uninstall.exe"
Delete "$SMPROGRAMS\Hybrid\*.*"
RMDir "$SMPROGRAMS\Hybrid"
RMDir /r $2
DeleteRegKey HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Hybrid"
; ; # 2
SetShellVarContext current
Delete "$DESKTOP\Hybrid.lnk"
Delete "$SMPROGRAMS\Hybrid\*.*"
RMDir "$SMPROGRAMS\Hybrid"
DeleteRegKey HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\Hybrid"
; # clear config directory ?
;SetShellVarContext current
; exist standart hybrid config direktory?
IfFileExists "$APPDATA\hybrid\*.*" "" jumpundelconfig
MessageBox MB_ICONQUESTION|MB_YESNO "$\r$\nDo you want to delete all of your Hybrid config files and settings?" IDNO jumpundelconfig
; YES? then delete Hybrid settings -> del DIR
RMDir /r "$APPDATA\hybrid"
jumpundelconfig:
SectionEnd
;,,,,,,,,,,,,,,,,,,,,,,,,,,,,,
;-----------------------------
;-----------------------------
;
; create uninstaller.exe and RegKeys
;
; - create uninstaller.exe and neccessary RegKeys
;-----------------------------
Section -End
WriteUninstaller "$INSTDIR\Uninstall.exe"
; # The registry entries simply add the Hybrid uninstaller to the Windowsuninstall list.
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Hybrid" "DisplayName" "Hybrid (remove only)"
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Hybrid" "UninstallString" '$INSTDIR\Uninstall.exe'
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Hybrid" "DisplayIcon" '$INSTDIR\Hybrid.exe'
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Hybrid" "InstallPath" '$INSTDIR'
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Hybrid" "HelpLink" "http://forum.selur.de/"
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Hybrid" "URLInfoAbout" "http://www.selur.de"
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Hybrid" "Publisher" "Selur´s Hybrid"
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Hybrid" "DisplayVersion" "${VERSION}"
WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Hybrid" "EstimatedSize" "0x00017318"
SectionEnd
;,,,,,,,,,,,,,,,,,,,,,,,,,,,,,
;-----------------------------
;-----------------------------
;
; Descriptions for the Components Page options
;
; - define the text lines that will be shown at the components page
;-----------------------------
!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
!insertmacro MUI_DESCRIPTION_TEXT ${Hybridmain} "Install all the provided files for Hybrid."
!insertmacro MUI_DESCRIPTION_TEXT ${Hybrid32} "The core executable needed for Hybrid to run."
!insertmacro MUI_DESCRIPTION_TEXT ${avsInfo} "This will install the 64bit avsInfo.exe for Hybrid. In case you want to use 64bit AviSynth Scripts on 64bit OS."
!insertmacro MUI_DESCRIPTION_TEXT ${ffmpeg} "This will install the 32bit ffmpeg.exe instead of the 64bit Version on a 64bit OS."
!insertmacro MUI_DESCRIPTION_TEXT ${delDef} "Reset the Hybrid settings to default values."
!insertmacro MUI_DESCRIPTION_TEXT ${avisynthext} "Install the Avisynth Extension."
!insertmacro MUI_DESCRIPTION_TEXT ${UserIniChoice} "You can specify your own settings directory. The place where Hybrid stores its settings."
!insertmacro MUI_DESCRIPTION_TEXT ${StartMenu} "Create shortcuts to access Hybrid from the Start Menu."
!insertmacro MUI_DESCRIPTION_TEXT ${desktop} "Create shortcut at the desktop."
!insertmacro MUI_DESCRIPTION_TEXT ${Shortcuts} "Shortcuts"
!insertmacro MUI_DESCRIPTION_TEXT ${Options} "Advanced Options"
!insertmacro MUI_DESCRIPTION_TEXT ${64bitosoptions} "Advanced 64bit OS Options"
!insertmacro MUI_FUNCTION_DESCRIPTION_END
;-----------------------------Leider wird jedoch (zumindest bei Win7&8) wenn man eine Desktopverknüpfung anlegt nicht nur eine Verknüpfung für den aktuellen user, sondern für alle User angelegt, obwohl "SetShellVarContext current" ja eigentlich gesetzt ist.
Sieht jemand den Fehler?
Cu Selur