Entspricht das hier etwa dem was Du machen willst? (mal vom nicht ordentlich eingestellten Overlay abgesehen, so das die Sterne immer durchschimmern?)
Falls, ja und falls Dich daran stört, dass es etwas so aussieht, als ob sich die Erde leicht wabert, dann ist das ein Effekt der daher kommt, dass das AskeptRatio des Vordergrundes nicht 1:1 ist. 
Cu Selur
Ja, das entspricht genau dem was dabei herauskommt wobei allerdings Vorder- und Hintergrund noch zusätzlich animiert sind, d.h die Erde dreht sich, der Sternenhintergrund hat auch eine Eigenbewegung und der Mond geht hinter der Erde auf.
Die Zwischendateien werden deshalb benötigt, weil sie noch anderweitig verwendet werden und als YUV vorliegen müssen, da ist es einfacher sie gleich in diesem Format abzuspeichern. Die Effekte sind nur Teil eines Premasterings für ein größeres Projekt, das dann auch nicht mehr mit AVISynth durchgeführt wird sondern mit kommerzieller Schnittsoftware, die direkt auf YUV zugreifen kann.
Außer den Astro-Clips werden u.a. Bryce-Landschaften und auch Fraktale verwendet. Um das alles unter einen Hut zu bekommen ist das System modular aufgebaut und der kleinste gemeinsame Nenner ist das Format 1024 x 576 YUV. Erst der letzte Schritt macht dann das Ergebnis anamorph und, da es mit 16:9-DV-Material zusammen geschnitten wird, (und als MPEG-2 auf DVD soll) auch interlaced.
Warum das ganze mit AVISynth? Weil ich keinem Interlacer traue von dem ich nicht weiß wie er es macht...:D:D:D
Natürlich können die Scripte kombiniert werden, sodaß gleich von FRAPS bis zum Overlay alles in einem Zug erledigt wird, aber dann fehlen mir die Einzeldateien.
Ich kann ein "reines" AVISkript erstellen, welches alle Schritte verbindet und es hier zur Verfügung stellen, kein Problem, kommt dann irgendwann morgen.
Den Vergleich zweier Files werde ich auch nochmals durchführen. Kann ja sein, daß mir ein Fehler unterlaufen ist 
Ich werde dazu auch noch mal die Funktion hier aus dem Threat neu abkupfern ...
Jedenfalls ist das Erdscheibchen in Deinem Beispiel-Clip schön ruhig, wenn ich es so mit YUV hinbekomme, dann bin ich zufrieden
Vielen Dank für die Hilfe !:daumen:
SixdeeBee
Guck auch mal, dass der Zoomfaktor das AspektRatio glatt teilt, dann sollte es auch ruhiger sein.
Bei dem Clip von mir hatte ich folgendes Skript verwendet:
Import("zooming.avs")
Hintergrund = ImageSource("g:\Hintergrund.png")
quelle = ImageSource("g:\Vordergrund.png")
mask = ImageSource("g:\Vordergrund2.png").convertToYUY2().Tweak(0.0, 0.0, 0.0, 10.0,coring=false)
Vordergrund = zooming(quelle,tWidth=1024,tHeight=576,coX=quelle.width(),coY=quelle.height, beginZoom=1.0/71,zoomFactor=71,steps=999)
return Overlay(Hintergrund.convertToRGB32(), Vordergrund.convertToRGB32(), mode="subtract", mask=mask).convertToYv12()Den Reverse Teil in deiner Anleitung kannst Du Dir sparen, wenn Du als beginZoom einen kleinen Wert nimmst. 
Danke für die Infos :daumen:
... der Zoomfaktor das AspektRatio glatt teilt ...
... Dann muß auch laufend gerundet werden, es ei denn, der Zoomfaktor arbeitet mit Integer und vergrößert Pixel-Sprungweise (quadratisch).
Dann explodiert die Erde aber ...:motz:
Dein Script entspricht im Kern genau meiner Vorgehensweise. Ich habe auch mal einen Test mit Deinen Vorgaben float(1/71) gemacht. Da war aber kein Unterschied zu jedem anderen beliebigen Zoomfaktor festzustellen.
Zur Verwendung von Reverse:
Dieser Filter verringert auch die Geschwindigkeit sehr deutlich. Der Grund für dessen Verwendung in der Entwicklungsversion war, daß beginnZoom und zoomFactor gemeinsam auf die kleinstmöglich erlaubte Bildgröße für den Resizer einwirken.
Beispiel:
Test 1:
beginZoom : 0.02
zoomFactor = 50 (= 1/ 0.02)
Keine Problem
Test 2:
beginZoom : 0.02
zoomFactor wird schrittweise verringert, bei 0.69 erscheint die Fehlermeldung:
Source image too small for this resize method
Fehler in den Zeilen (der ZoomFunktion): 131, 86, 57, 17
Test 3:
beginnZoom = 0.5
zoomFactor wird schrittweise verringert, bei 0.027 erscheint die gleiche Fehlermeldung.
Enthalten beginnZoom und zoomFactor Vorgaben im Wertebereich < 1, dann besteht die Gefahr, daß die Bilddimensionen zu klein werden und es erfolgt ein Absturz.
Da das Skript AvsP-orientiert ist hat man einen Schiebesteller sehr schnell mal zu weit nach links gerückt und dann erfolgt eine Fehlermeldung, deren Ursache nur noch mittels manueller Korrektur im Skript selbst beseitigt werden kann, da AvsP die letzte Stellung gespeichert hat und danach immer wieder mit der gleichen Fehlermeldung startet.
Das war mir zu mühsam, da es immer wieder von anderen Problemen abgelenkt hat ...
Nach vielen Tests bin ich wieder bei der "schmutzigen" Methode angekommen: Hochskaliereng mit einem konstanten Faktor, Zoomen, dann Rückskalierung auf das Ausgangsformat. Das schmeckt mir wegen des zusätzlichen 2-maligen Skalierens zwar nicht ... aber man kann nur in den Schuhen tanzen die man hat ...
Als Anlage sind 3 Dateien angehängt.
zoom_1024x576.avi => ohne Hochskalierung, maximales Wackeln
zoom_4096x2304.avi => mit 4-facher Hochskalierung in X- und Y-Richtung.
zoom_diff.avi => das "Fehlersignal" zoom_1024x576 minus zoom_4096x2304
Je größer k desto sauberer die Bewegung, Besitzer einer single-core CPU seien aber davor gewarnt, auch nur an k = 8 zu denken. 
Mein alter Athlon K-7 3200+ braucht damit für einen 2 Minuten Clip einen halben Tag Rechenzeit. Als guter Kompromiß für schnelle PCs sind k = 4.
Die 4. Datei ist eine veränderte Version von Zoom_in_out_1.ses, mit ihr erreicht man, je nach gewähltem Faktor k, eine wesentlich höhere Bearbeitungsgeschwindigkeit. Der Trick ist, daß jetzt mit unterschiedlichen Multiplikatoren für die X- und Y-Richtung gearbeitet werden kann.
X-Richtung: k = 1 bis k = 8
Y-Richtung: k = 1 bis k = 4
Da das Wackeln hauptsächlich in X-Richtung auftritt, sollte der Multiplikator dort auch mehr greifen als in Y-Richtung.
Im Vergleich von kx = ky = 4 mit z.B. kx = 4, ky = 1 läuft letztere Version auch fast 4 mal
schneller.
Der Einstellbereich von beginnZoom wurde jetzt nach unten auf 0.02 erweitert (gemäß Deinem Vorschlag :daumen: ). Aber Achtung! Jetzt kann man mit den Schiebern Start-Endpunkt und Zoomfaktor einen Absturz herbeiführen. Für den Fall des Falles stehen in der REM-Zeile über der Zoom-Befehlszeile die Sollvorgaben.
Eine weitere Änderung ist, daß Tweak jetzt abschaltbar ist. Damit spart man sich dessen Durchlaufzeit wenn weder Farb- noch Luminanz-Änderungen benötigt werden.
Ich denke, daß wir es mal auf diesem Stand belassen können. Wie das Beispiel in Zoom_4096_2304 zeigt, läßt sich ein sauberer Bewegungspfad über das Hochskalieren erreichen. Da es sich hierbei um eher seltener verwendete "Specialeffects" handelt, kommt es auf die längere Rechenzeit nicht an.
Danke für die Hilfe, Hinweise und Tips !:cheers:
SixdeeBee
Zur Erläuterung: Das Problem mit dem Absturz liegt halt daran, dass Resizer eine MindestBildtgröße erwarten, wird diese durch Zoom unterschritten steigt der Resizer aus.
Cu Selur
Ps.: Könntest Du das .ses Skript auch als .avs Skritp dazupacken?
Ja, wird noch nachgeliefert. Wenn keine Einwände Deinerseits bestehen, werde ich die Skalierung aber vorher noch in Deine Zoom-Funktion einbauen. Dazu muß ich aber erst mal den Code richtig verstehen ...:) (da sind ja einige Verschachtelungen drinne ...) oder aber - Wink mit dem Zaunpfahl - 
... Du implementierst kx und ky und ich übernehme es dann in das "AVISynth-Puristen-Skript" ...:D
SixdeeBee
Mir ist irgendwie nicht so ganz klar wo Du die Parameter rein haben willst, als das es Sinn macht dies nicht extern zu machen.
Mein Problem ist, ich kann das Wackeln, was Du hast nicht nachstellen, mit dem Du ' zoom_1024x576.avi' erzeugt hast.
-> Wie sieht dein zooming(..)-Aufruf da aus?
Ok, hier das komplette Zoom-Skript:
# ZoomInOut_1
# Quellformat: 1024 x 576, YUV 50fps progressiv
# Ausgangsformate: 1024x576 oder 720x576 (anamorph)
# 50fps progressiv / 25fps interlaced (BFF)
#
SetMemoryMax(1024)
#
LoadPlugin("C:\Programme\AviSynth 2.5\dll\mt.dll")
LoadPlugin("C:\Programme\AviSynth 2.5\dll\LimitedSupport_03Dec05.dll")
LoadPlugin("C:\Programme\AviSynth 2.5\dll\mt_MaskTools.dll")
LoadPlugin("C:\Programme\AviSynth 2.5\dll\RemoveGrain.dll")
LoadPlugin("C:\Programme\AviSynth 2.5\dll\MaskTools.dll")
#
Import("C:\Programme\AviSynth 2.5\functions\Zoom.avs")
Import("C:\Programme\AviSynth 2.5\Functions\LimitedSharpenS.avsi")
Import("C:\Programme\AviSynth 2.5\Functions\YLevels.avsi")
#
SetMTMode(2)
#
AviSource("quelle.avi",false,pixel_type="YUY2")
#
kx=4
ky=1
GaussResize(kx*1024,ky*576,p=50.0)
zooming(tWidth=kx*1024,tHeight=ky*576,coX=width(),coY=height,beginZoom=(0.02),zoomFactor=50.0,steps=3000)
#
a=0
#
a == 1 ? GaussResize(704,576,p=50.0).AddBorders(8,0,8,0) : GaussResize(1024,576,p=50.0)
#
#######################################################################
#
### AvsP marked script ###
# # ZoomInOut_1
# # Quellformat: 1024 x 576, YUV 50fps progressiv
# # Ausgangsformate: 1024x576 oder 720x576 (anamorph)
# # 50fps progressiv / 25fps interlaced (BFF)
# #
# SetMemoryMax(1024)
# #
# LoadPlugin("C:\Programme\AviSynth 2.5\dll\mt.dll")
# LoadPlugin("C:\Programme\AviSynth 2.5\dll\LimitedSupport_03Dec05.dll")
# LoadPlugin("C:\Programme\AviSynth 2.5\dll\mt_MaskTools.dll")
# LoadPlugin("C:\Programme\AviSynth 2.5\dll\RemoveGrain.dll")
# LoadPlugin("C:\Programme\AviSynth 2.5\dll\MaskTools.dll")
# #
# Import("C:\Programme\AviSynth 2.5\functions\Zoom.avs")
# Import("C:\Programme\AviSynth 2.5\Functions\LimitedSharpenS.avsi")
# Import("C:\Programme\AviSynth 2.5\Functions\YLevels.avsi")
# #
# SetMTMode(2)
# #
# AviSource("quelle.avi",false,pixel_type="YUY2")
# #
# kx=[<'X-Multiplikator', 1, 8, 4>]
# ky=[<'Y-Multiplikator', 1, 4, 1>]
# GaussResize(kx*1024,ky*576,p=50.0)
#
# zooming(tWidth=kx*1024,tHeight=ky*576,coX=width(),coY=height, beginZoom=([<'Start-Endpunkt', 0.02, 5.0, 0.02>]),zoomFactor=[<'Zoomfaktor Out', 0.02, 100, 50.0>],steps=[<'Bearbeitete Frames', 10, 5000, 3000>])
# #
# a=0
# [Anamorph=0]
# a=1
# [/Anamorph]
# #
# a == 1 ? GaussResize(704,576,p=50.0).AddBorders(8,0,8,0) : GaussResize(1024,576,p=50.0)
# #
# [Scharf ein-aus=0]
# SetMTMode(0)
# Mt("LimitedSharpenFaster(ss_x=1.5,ss_y=1.5,Smode=4,Strength=[<'Kanten',1,400,100>],Lmode=2,overshoot=0,soft=24)")
# SetMTMode(2)
# [/Scharf ein-aus]
# #
# [Farbe und Luminanz=0]
# Tweak([<'Farbe', -180, 180, 0.0>],[<'Saettigung', 0.0, 10.0, 1.0>],[<'Helligkeit', -128, 128, 0.0>],[<'Kontrast', 0.5, 5.0, 1.0>],coring=false,sse=true)
# [/Farbe und Luminanz]
# #
# [Gammakorrektur=0]
# ConvertToYV12(interlaced=false).YLevels(0,[<'Gammakorrektur', 0.5, 5, 1.0>],255,0,255).ConvertToYUY2(interlaced=false)
# [/Gammakorrektur]
# #
# [Reverse=0]
# reverse()
# [/Reverse]
# #
# [Interlacer=0]
# AssumeBFF().SeparateFields().SelectEvery(4,0,3).Weave()
# [/Interlacer]
### AvsP marked script ###
Für Dich interessant sein dürfte der Abschnitt oberhalb der Trennlinie. Dort wird nur die Zoom-Funktion aufgerufen.
Die Abfrage
a= 0
a == 1 ? .... entscheidet, ob in das Ursprungsformat oder anamorph reskaliert werden soll.
SixdeeBee
Edit: Habe Deine Frage übersehen, sorry. Der Aufruf von Zoom_1024x576 erfolgte ohne den Resizer und ohne ky und kx also folgendermaßen:
zooming(tWidth=1024,tHeight=576,coX=width(),coY=height,beginZoom=(0.02),zoomFactor=50.0,steps=3000)
SixdeeBee
Import("zooming.avs")ImageSource("g:\Vordergrund.png", end=2999, fps=25.0)return zooming(tWidth=1024,tHeight=576,coX=width(),coY=height(),beginZoom=(1024.0/576.0/100.0),zoomFactor=50.0,steps=2999)Läuft glatt und ohne Probleme, wie ich vermutet habe liegt es daran, dass das AspektRatio des Clips sich nicht gut durch den Zoom teilen lassen.
-> wenn Du Denn beginZoom also wie bei mir auf:
beginZoom=(1024.0/576.0/100.0)setzt sollte alles glatt laufen
-> Korrektur wackelt immer noch,... ich guck die Tage nochmal drauf hab die Woche aber leider kaum Zeit 
Guck mal http://selur.movie2digital.com/earth.mp4
das liefert oberer Aufruf, wenn ich die 'cWidth + 1'-Änderungen nicht vornehme.
...hab die Woche aber leider kaum Zeit ... Überhaupt kein Problem. Wie schon erwähnt komme ich mit dem Hochskalieren klar. Als Anlage mal ein Overlay, erstellt mit kx=6 und ky=2. Leider wird durch die extreme Kompression die Qualität sehr schlecht (das Original ist 320 MB groß), man kann aber gut erkennen, wie die Erde "sanft" nach vorne kommt.
Der Hintergrund ist animiert, im Original funkeln die Sterne ganz natürlich.
Den Test mit beginZoom=(1024.0/576.0/100.0) habe ich auch gemacht, leider ohne Erfolg :nein:
Hier noch das aktuelle Overlay-Skript in Semi-Klartext:
### AvsP marked script ###
# # Schwarzweiß-Stanzer
# #
# # Widescreen 16:9 / Fullscreen 4:3
# # Quellen: YUV 50fps-progr.
# #
# # quelle_1 = Hintergrund
# # quelle_2 = Vordergrund
# #
# SetMemoryMax(1024)
# #
# LoadPlugin("C:\Programme\AviSynth 2.5\dll\mt.dll")
# LoadPlugin("C:\Programme\AviSynth 2.5\dll\MaskTools.dll")
# LoadPlugin("C:\Programme\AviSynth 2.5\dll\LimitedSupport_03Dec05.dll")
# LoadPlugin("C:\Programme\AviSynth 2.5\dll\mt_MaskTools.dll")
# LoadPlugin("C:\Programme\AviSynth 2.5\dll\RemoveGrain.dll")
# #
# Import("C:\Programme\AviSynth 2.5\Functions\LimitedSharpenS.avsi")
# Import("C:\Programme\AviSynth 2.5\Functions\YLevels.avsi")
# #
# a=AviSource("quelle_1.avi",false,pixel_type="YUY2")
# b=AviSource("quelle_2.avi",false,pixel_type="YUY2")
# #
# SetMTMode(2)
# #
# mask=b.Tweak(0.0, 0.0, 0.0, 10.0,coring=false,sse=true).Tweak(0.0, 0.0, 0.0, 10.0,coring=false,sse=true)
# #
# [Scharf-1 ein-aus=0]
# SetMTMode(0)
# a=a.Mt("LimitedSharpenFaster(ss_x=1.5,ss_y=1.5,Smode=4,Strength=[<'Kanten-1',1,400,50>],Lmode=2,overshoot=0,soft=24)")
# SetMTMode(2)
# [/Scharf-1 ein-aus]
# [Scharf-2 ein-aus=0]
# SetMTMode(0)
# b=b.Mt("LimitedSharpenFaster(ss_x=1.5,ss_y=1.5,Smode=4,Strength=[<'Kanten-2',1,400,50>],Lmode=2,overshoot=0,soft=24)")
# SetMTMode(2)
# [/Scharf-2 ein-aus]
# #
# a=a.Tweak([<'Farbe-1', -180, 180, 0.0>],[<'Saettigung-1', 0.0, 10.0, 1.0>],[<'Helligkeit-1', -128, 128, 0.0>],[<'Kontrast-1', 0.5, 5.0, 1.0>],coring=false,sse=true)
# b=b.Tweak([<'Farbe-2', -180, 180, 0.0>],[<'Saettigung-2', 0.0, 10.0, 1.0>],[<'Helligkeit-2', -128, 128, 0.0>],[<'Kontrast-2', 0.5, 5.0, 1.0>],coring=false,sse=true)
# #
# [Gammakorrektur-1=0]
# a=a.ConvertToYV12(interlaced=false).YLevels(0,[<'Gammakorrektur-1', 0.5, 5, 1.0>],255,0,255).ConvertToYUY2(interlaced=false)
# [/Gammakorrektur-1]
# [Gammakorrektur-2=0]
# b=b.ConvertToYV12(interlaced=false).YLevels(0,[<'Gammakorrektur-2', 0.5, 5, 1.0>],255,0,255).ConvertToYUY2(interlaced=false)
# [/Gammakorrektur-2]
# #
# Overlay(a,b,[<'Overlay X-Verschiebung', -1024, +1024, 0>],[<'Overlay Y-Verschiebung', -576, +576, 0>],mask)
# #
# [Anamorph=0]
# GaussResize(704,576,p=50.0).AddBorders(8,0,8,0)
# [/Anamorph]
# #
# [Reverse-1=0]
# a=a.reverse()
# [/Reverse-1]
# #
# [Reverse-2=0]
# b=b.reverse()
# [/Reverse-2]
# #
# [Interlaced=0]
# AssumeBFF().SeparateFields().SelectEvery(4,0,3).Weave()
# [/Interlaced]
### AvsP marked script ###
SixdeeBee
hab mal quick&dirty die kX und kY Faktoren reingepackt und die Aufrufe nach außen vereinfacht, so dass sie deinen Vorgaben entsprechen sollten,...
function zooming2(clip clp, int "mulX", int "mulY", float "beginZoom", float "zoomFactor", int "steps"){
#mulX/Y >= 1 garantieren
mulX = default(Float( (mulX < 1) ? 1 : mulX), 1.0)
mulY = default(Float( (mulY < 1) ? 1 : mulY), 1.0)
outWidth = clp.width
outHeight = clp.height
clp = clp.Spline36Resize(int(outWidth*mulY), int(outHeight*mulX))
#DEFAULTS:
tWidth = clp.width()
tHeight = clp.height()
beginZoom = default(beginZoom, 1.0/calcInitFactor(clp, tWidth, tHeight ))
zoomFactor = default(zoomFactor, 6.0)
steps = default(steps, 100)
#FUNCTION:
end = steps
clp.duplicateframe(0).trim(2,2).loop(steps+1)
Animate(0,steps-1,"linearzoom", clp, tWidth, tHeight, tWidth, tHeight, beginZoom, zoomFactor, 0, steps, \
clp, tWidth, tHeight, tWidth, tHeight, beginZoom, zoomFactor, steps, steps )
return GaussResize(last, outWidth, outHeight, p=50)
}guck mal ob es damit bei Dir glatt läuft,...
Werde mich aber wohl nochmal damit beschäftigen müssen und mir da irgendwas konditionales Einfallen lassen müssen, Problem ist daran nur, dass Avisynth keine ordentliche if/else-Strukturen Unterstützt und auch der ?-Operator nur bedingt brauchbar ist.
Cu Selur
Ps.: Wenn Du die [ code ] [ / code ] Tags des Boards benutzen würdest wären die Skripte vielleicht leserlicher, dann die ganzen # verwirren schon.
Versuch mal folgendes:
function zooming(clip clp, int "tWidth", int "tHeight", float "coX", float "coY", float "beginZoom", float "zoomFactor", int "steps"){
#DEFAULTS:
tWidth = default(tWidth, 720)
tHeight = default(tHeight, 576)
cWidth = clp.width
cHeight = clp.height
coX = default(coX, Float(cWidth)/2.0)
coY = default(coY, Float(cHeight)/2.0)
beginZoom = default(beginZoom, 1.0/calcInitFactor(clp, tWidth, tHeight ))
zoomFactor = default(zoomFactor, 6.0)
steps = default(steps, 100)
#FUNCTION:
end = steps
clp.duplicateframe(0).trim(2,2).loop(steps+1)
Animate(0,steps-1,"linearzoom", clp, tWidth, tHeight, coX, coY, beginZoom, zoomFactor, 0, steps, \
clp, tWidth, tHeight, coX, coY, beginZoom, zoomFactor, steps, steps )
}
function zoomedWalk(clip clp, int "tWidth", int "tHeight", float "startX", float "startY", float "targetX", float "targetY", float "zoom", int "steps"){
#DEFAULTS:
tWidth = default(tWidth, 720)
tHeight = default(tHeight, 576)
cWidth = clp.width
cHeight = clp.height
zoom = default(zoom, 1/calcInitFactor(clp, tWidth, tHeight )*4)
startX = default(startX, Float(tWidth)/2)
startY = default(startY, Float(tHeight)/2)
targetX = default(targetX, cWidth)
targetY = default(targetY, startY)
steps = default(steps, 1000)
#FUNCTION:
end = steps
clp.duplicateframe(0).trim(2,2).loop(steps+1)
Animate(0,steps-1,"linearzoom", clp, tWidth, tHeight, startX, startY, zoom, 1.0, 0, steps,\
clp, tWidth, tHeight, targetX, targetY, zoom, 1.0, steps, steps).trim(0,steps).trim(0,steps-1)
}
function linearZoom(clip clp, int "tWidth", int "tHeight", float "coX", float "coY", float "beginZoom", float "zoomFactor", int "step", int "steps"){
#DEFAULTS:
tWidth = default(tWidth, 720)
tHeight = default(tHeight, 576)
cWidth = clp.width
cHeight = clp.height
coX = default(coX, Float(cWidth)/2)
coY = default(coY, Float(cHeight)/2)
beginZoom = default(beginZoom, 1/calcInitFactor(clp, tWidth, tHeight ))
zoomFactor = default(zoomFactor, 5.0)
steps = default(steps, 100)
step = default(step, steps)
#FUNCTION:
chunk = pow(zoomFactor, Float(step)/steps)
factor = beginZoom * chunk
return zoom(clp, tWidth, tHeight, coX, coY, factor)
}
function zoom(clip clp, int "tWidth", int "tHeight", float "coX", float "coY", float "factor"){
#DEFAULTS:
tWidth = default(tWidth, 720)
tHeight = default(tHeight, 576)
cWidth = clp.width()
cHeight = clp.height()
coX = default(coX, Float(cWidth)/2)
coY = default(coY, Float(cHeight)/2)
factor = default(factor, 1.0)
#FUNCTION:
#src_left + src_top: linke obere Ecke des Viewports in Clip-Koordinaten
src_left = coX-(tWidth/factor/2)
src_top = coY-(tHeight/factor/2)
#src_right + src_bottom: rechte untere Ecke des Viewports in Clip-Koordinaten
src_right = coX+(tWidth/factor/2)-cWidth
src_bottom = coY+(tHeight/factor/2)-cHeight
#anchorX = (src_left < 0 && src_right <= 0) ? (0.0) : ( (src_left >= 0 && src_right > 0) ? (tWidth - 1.0) : (tWidth/2.0) )
anchorX = (src_left < 0 && src_right <= 0) ? (0.0) : ( (src_left >= 0 && src_right > 0) ? (tWidth) : (tWidth/2.0) )
#anchorY = (src_top < 0 && src_bottom <= 0) ? (0.0) : ( (src_top >= 0 && src_bottom > 0) ? (tHeight - 1.0) : (tHeight/2.0) )
anchorY = (src_top < 0 && src_bottom <= 0) ? (0.0) : ( (src_top >= 0 && src_bottom > 0) ? (tHeight) : (tHeight/2.0) )
coX = (anchorX == 0.0) ? (0.0) : ( (anchorX == tWidth - 1.0) ? (cWidth - 1.0) : (coX) )
coY = (anchorY == 0.0) ? (0.0) : ( (anchorY == tHeight - 1.0) ? (cHeight - 1.0) : (coY) )
zoomWithAnchor(clp, tWidth, tHeight, coX, coY, anchorX, anchorY, factor)
}
function zoomWithAnchor(clip clp, int "tWidth", int "tHeight", float "coX", float "coY", float "anchorX", float "anchorY", float "factor"){
#DEFAULTS:
tWidth = default(tWidth, 720)
tHeight = default(tHeight, 576)
cWidth = clp.width()
cHeight = clp.height()
coX = default(coX, Float(cWidth)/2)
coY = default(coY, Float(cHeight)/2)
anchorX = default(anchorX, Float(tWidth)/2)
anchorY = default(anchorY, Float(tHeight)/2)
factor = default(factor, 1.0)
#FUNCTION:
#src_left + src_top: linke obere Ecke des Viewports in Clip-Koordinaten
src_left = coX-(anchorX/factor)
src_top = coY-(anchorY/factor)
#src_right + src_bottom: rechte untere Ecke des Viewports in Clip-Koordinaten
src_right = coX+((tWidth - anchorX)/factor)
src_bottom = coY+((tHeight - anchorY)/factor)
p_top = (src_top < 0) ? ( Int(-src_top * factor) ) : (0)
p_left = (src_left < 0) ? ( Int(-src_left * factor) ) : (0)
p_right = (src_right >= cWidth) ? ( Int((src_right-cWidth + 1) * factor) ) : (0)
p_bottom = (src_bottom >= cHeight) ? ( Int((src_bottom-cHeight + 1) * factor) ) : (0)
p_left = (p_left+p_right)/2
p_right = p_left
p_top = (p_top+p_bottom)/2
p_bottom = p_top
lrtWidth = tWidth - p_left - p_right
lrtHeight = tHeight - p_top - p_bottom
lrTop = (src_top < 0) ? (0) : (src_top)
lrLeft = (src_left < 0) ? (0) : (src_left)
lrWidth = (src_right >= cWidth) ? (cWidth - lrLeft) : (src_right - lrLeft)
lrHeight = (src_bottom >= cHeight) ? (cHeight - lrTop) : (src_bottom - lrTop)
clp = clp.BlackmanResize(lrtWidth, lrtHeight, lrLeft, lrTop, lrWidth, lrHeight)
clp = AddBorders(clp, p_left, p_top, p_right, p_bottom)
return clp
}
#calculates inital zoomfactor to fit the whole source image into tWidthxtHeight
function calcInitFactor(clip clp, int "twidth", int "theight"){
#DEFAULTS:
twidth = default(twidth, 720)
theight = default(theight, 576)
cwidth = clp.width()
cheight = clp.height()
#FUNCTION:
wdiff = Float(cwidth)/twidth
hdiff = Float(cheight)/theight
return ((wdiff >= hdiff) ? wdiff : hdiff)
}
mit:
zooming(tWidth=1024,tHeight=576,coX=width(),coY=height(),beginZoom=(1024.0/576.0/100.0),zoomFactor=50.0,steps=3000)
also ohne k, hab da eine Kleinigkeit an der Wahl des Ankers geändert, was eventuell für das Problem verantwortlich ist.
Oha, da gibt es wieder viel zu testen ...:)
Was die [ code ] [ / code ] Tags betrifft: Die Darstellung wurde nicht vom Board erzeugt, sondern von AvsP. Das speichert ein Skript doppelt ab, einmal komplett mit allen Schaltern und Slidern und einmal als pures, also lauffähiges AVISynth-Skript. In letzterem sind aber alle Filter, die abgeschaltet wurden, nicht enthalten. Um alle Filter zu zeigen, habe ich einfach die erste Variante gewählt und deren Darstellung ist "rautenbasiert gerahmt" ...:zunge:
Da es nur zur Information dienen sollte (man kann alle Infos, die benötigt werden, aus dieser Darstellung extrahieren...) wurde es halt "dirty and quick" so dargestellt. Wenn die Rauten stören, ... gelobe ich Besserung...:D
Betrteffs des neuen Codes melde ich heute abend wieder.
Danke für die Arbeit !!!:daumen:
SixdeeBee
Keine Eile hab Mi-Fr immer von 8 bis ca. 21 Uhr Programm und deshalb eh kaum Zeit
Keine Eile hab Mi-Fr immer von 8 bis ca. 21 Uhr Programm und deshalb eh kaum Zeit
... ja natürlich, Real-Life geht vor !:)
Hier ein kurzer Erfahrungsbericht bez. Deiner Vorschläge von #71 und #72:
1. Die große Funktionensammlung aus #72:
Die AVISynth 2.57 MT-Version hat den Blackman-Resizer nicht implementiert und zeigt eine Fehlermeldung. Habe stattdessen notgedrungen einen anderen Resizer einbauen müssen, habe alle durchprobiert und bin wieder beim Gauss hängengeblieben. (ich mag Polgüten <= 0.5 !!!)
Das Bild wackelt wie bisher.
2. Der neue Funktionskopf aus #71
Funktioniert, jedoch bei mulX = mulY = 0 (keine Eingabe) erscheint die Fehlermeldung > Evaluate: operands of "<" and friends must be string or numeric "
Ich habe den Kopf folgendermaßen geändert:
mulX = default(Float( (mulX < 1) ? 1 : mulX), 1.0)
mulY = default(Float( (mulY < 1) ? 1 : mulY), 1.0)
wurde durch
mulX = default(mulX,1)
mulY = default(mulY,1)
mulX = ABS(mulX)
mulY = ABS(mulY)
ersetzt.
ABS(...) um negative Vorgaben zu blockieren, dürfte aber normalerweise nicht nötig sein.
Dann ist mir aufgefallen, daß in der Zeile
clp = clp.Spline36Resize(int(outWidth*mulY), int(outHeight*mulX))
die Breite mit mulY und die Höhe mit mulX multipliziert wird. Ist das so gewollt ? Ich habs mal umgedreht und es funktioniert damit.
Den geänderten Funktionskopf von #71 habe ich auch in die Funktion von #72 eingebaut.
Ergebnis:
1. Die Geschwindigkeit ist geringer als mit der Vorgängerversion. Eine mulX=4 - mulY=2
Konversion dauert so lange wie mulX=6 (kx=6) - mulY=2 (ky=2) mit der Vorgängerversion.
2. Das Rest-Wackeln erscheint mir trotz Hochskalierung etwas stärker zu sein als mit der Vorgängerversion, insbesonders wenn das Erdscheibchen noch klein ist, taumelt es noch sichtbar hin- und her.
3. Mit dem Spline36Resizer hatte ich seltsamerweise mehrere Bluescreens mit der Fehlermeldung > Memory_Management <. Nachdem er durch den Gauss ersetzt worden war, traten die Bluescreens nicht mehr auf. Ob das aber der wahre Grund gewesen ist, hat mir der PC nicht verraten ...:D
SixdeeBee
die Breite mit mulY und die Höhe mit mulX multipliziert wird. Ist das so gewollt ?
Nein (Typo :))
Interessant ist vor allem #72, komisch das Spline36Resize Probleme macht, geht bei mir ohne Probleme.
Cu Selur
Auf dem K-7 (= ohne MT) funktioniert es ohne Absturz. Dauert halt ein kleine Ewigkeit bis damit ein Clip fertig ist. Mitten in der Nacht hatte ich keine Lust mehr, das Ergebnis abzuwarten (hätte bis 5 Uhr in der Früh gedauert ;D;D), wird heute nachgeholt.
SixdeeBee
MT nutz ich gar nicht, da ich mit x264 encode ist meine CPU auch so immer voll ausgelastet
So, melde mich mal wieder... nachdem ich heute eine richtige Testorgie absolviert habe, denn der Bluescreen trat jetzt auch mit dem GaussResizer auf.
Den Bösewicht konnte ich entnervt nach einigen Stunden identifizieren.
Hatte vorgestern, entgegen meiner Absicht, probeweise Premiere 6.5 installiert, weil jemand damit Probleme hat und ich diese halt nachvollziehen wollte. Und was soll man dazu sagen ... nach dem Start von Premiere bleibt beim Verlassen eine Datei > AOM.dll < im Speicher zurück und die hat nicht nur Kollisionen mit AVISynth verursacht ...:motz: sondern auch die Rechengeschwindigkeit reduziert :mad: Nachdem ich den Geisterfahrer entfernt hatte, funktionierte auch der SplineResizer ...
SixdeeBee
Sie haben noch kein Benutzerkonto auf unserer Seite? Registrieren Sie sich kostenlos und nehmen Sie an unserer Community teil!