progressive-telecined-interlaced

[size=8]# === DLLs ===
# - mt_masktools-25.dll
# - MedianBlur.dll
# - removegrain.dll
# - fluxsmooth.dll
# - MVTools.dll (v2 branch)
#
# === Scripts ===
# - LimitedSharpenFaster.avs
#
# Helper script functions included below:
# - sbr() -- highpass blur function (maybe floating in the forums, but is well-hidden)
# - TGMC_inflate/deflate -- faster variants of MaskTools filters, same as in TGMC
# - MinBlur() -- Gauss/Median combination, same as in MCBob




o = last


med1 = o.minblur(1)
med2 = o.minblur(2)
e1   = med2.mt_edge("prewitt",0,255,0,255).mt_inflate()
e2   = mt_lutxy(e1,e1.mt_expand().TGMC_deflate().mt_expand().TGMC_deflate().mt_expand(),"y x -").TGMC_inflate().levels(32,2.0,255,0,255,false)


o1   = o.mt_merge(med1,e2,U=2,V=2)
o2   = o.mt_merge(med2,e2,U=2,V=2)


rg11  = o1.removegrain(11)
sbrr  = o2.sbr()
rg4   = sbrr.removegrain(4)
s0    = o1.mt_adddiff(mt_makediff(sbrr,rg4),U=2,V=2)
s00   = s0.sharpen(0.49)
s00a  = s0.limitedsharpenfaster(ss_x=1.0,ss_y=1.0,strength=76,soft=26) 
s00   = s00.mt_merge(s00a,e2,U=2,V=2)
s0    = s00.mt_makediff(mt_makediff(s00,s0).blur(1),U=2,V=2)
s0    = mt_lutxy(o1,s0,"x x y - abs 1 2 / ^ 2 * x y - x y - abs 0.001 + / * -",U=2,V=2)


ME_NR = o.fluxsmootht(11).merge(o,0.49).removegrain(11)


sup0  = ME_NR.MSuper(pel=2,sharp=2)
s0sup = s0.MSuper(pel=2,sharp=2,levels=1)
sup   = o.Msuper(pel=2,sharp=2,levels=1)


fv3   = sup0.MAnalyse(isb=false,delta=3,blksize=16,overlap=8,truemotion=true,search=4)	# ,truemotion=false
fv2   = sup0.MAnalyse(isb=false,delta=2,blksize=16,overlap=8,truemotion=true,search=4)	# ,truemotion=false
fv1   = sup0.MAnalyse(isb=false,delta=1,blksize=16,overlap=8,truemotion=true,search=4)	# ,truemotion=false
bv1   = sup0.MAnalyse(isb=true, delta=1,blksize=16,overlap=8,truemotion=true,search=4)	# ,truemotion=false
bv2   = sup0.MAnalyse(isb=true, delta=2,blksize=16,overlap=8,truemotion=true,search=4)	# ,truemotion=false
bv3   = sup0.MAnalyse(isb=true, delta=3,blksize=16,overlap=8,truemotion=true,search=4)	# ,truemotion=false


mdg2_1  = sbrr.MDegrain2(s0sup,bv1,fv1,bv2,fv2,thSAD=288)
mdg2_1s = mdg2_1.limitedsharpenfaster(ss_x=1.0,ss_y=1.0,strength=74)
mdg2_2  = mdg2_1.MDegrain2(mdg2_1s.MSuper(pel=2,sharp=2,levels=1),bv1,fv1,bv3,fv3,thSAD=288)
mdg2_2a  = mt_lutxy(mdg2_2,o,"x 1 + y < x 1 + x 1 - y > x 1 - x ? ?",U=2,V=2) 


stackhorizontal(mdg2_2a,o)


return(last)




# === Helpers ===


# highpass'ed blur. Don't ask why I named it 'sbr' - I don't remember.
function sbr(clip c) {
rg11D=mt_makediff(c,c.removegrain(11,-1))
rg11DD=mt_makediff(rg11D,rg11D.removegrain(11,-1)).mt_lutxy(rg11D,"x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?")
c.mt_makediff(rg11DD,U=2,V=2) }


# Re-builds of mt_inflate & mt_deflate. These rebuilds are faster than the originals.
function TGMC_inflate(clip c,int"Y",int "U",int "V") {
mtY=default(Y, 3) mtU=default(U, 1) mtV=default(V, 1)
rgY=(mtY==3)?20:-1 rgU=(mtU==3)?20:-1 rgV=(mtV==3)?20:-1 
mt_logic(c,c.removegrain(rgY,rgU,rgV),"max",Y=mtY,U=mtU,V=mtV) }


function TGMC_deflate(clip c,int"Y",int "U",int "V") {
mtY=default(Y, 3) mtU=default(U, 1) mtV=default(V, 1)
rgY=(mtY==3)?20:-1 rgU=(mtU==3)?20:-1 rgV=(mtV==3)?20:-1 
mt_logic(c,c.removegrain(rgY,rgU,rgV),"min",Y=mtY,U=mtU,V=mtV) }




# Nifty Gauss/Median combination
function MinBlur(clip clp, int r, int "uv")
{
uv   = default(uv,3)
uv2  = (uv==2) ? 1 : uv
rg4  = (uv==3) ? 4 : -1
rg11 = (uv==3) ? 11 : -1
rg20 = (uv==3) ? 20 : -1
medf = (uv==3) ? 1 : -200


RG11D = (r==1) ? mt_makediff(clp,clp.removegrain(11,rg11),U=uv2,V=uv2)
 \    : (r==2) ? mt_makediff(clp,clp.removegrain(11,rg11).removegrain(20,rg20),U=uv2,V=uv2)
 \    :          mt_makediff(clp,clp.removegrain(11,rg11).removegrain(20,rg20).removegrain(20,rg20),U=uv2,V=uv2)
RG4D  = (r==1) ? mt_makediff(clp,clp.removegrain(4,rg4),U=uv2,V=uv2)
 \    : (r==2) ? mt_makediff(clp,clp.medianblur(2,2*medf,2*medf),U=uv2,V=uv2)
 \    :          mt_makediff(clp,clp.medianblur(3,3*medf,3*medf),U=uv2,V=uv2)
DD    = mt_lutxy(RG11D,RG4D,"x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?",U=uv2,V=uv2)
clp.mt_makediff(DD,U=uv,V=uv) #.subtitle("free")
return(last)
}[/size]