High School Musical

Oneboy1979

HI Leute,

hab mir vor ca. 2 Wochen am Disney Channel High School Musical aufgenommen, leider sendet mein Receiver immer interlace Material zum Recorder, meine Frage, wie kann ich aus diesem Material ein XVID erzeugen, welches gut aussieht. Zeit spielt keine Rolle, und Dateigröße auch nicht.

http://rapidshare.com/files/33063684/Sample.mpg.html

Bevor ichs vergesse mit diesem Script hab ichs schon probiert (war aber nicht das gelbe vom ei):

Code

#LoadPLugin("C:\DGIndex\DGDecode.dll")
LoadPlugin("D:\DVD\DGIndex\DGDecode.dll")
LoadPlugin("C:\Avis\mpasource.dll")
LoadPlugin("C:\Avis\asharp.dll")
LoadPlugin("C:\Avis\Deen.dll")
LoadPlugin("C:\Avis\FluxSmooth.dll")
LoadPlugin("C:\Avis\undot.dll")
LoadPlugin("C:\Avis\unfilter.dll")
LoadPlugin("C:\Avis\peachsmoother.dll")
LoadPlugin("C:\Avis\DeGrainMedian.dll")
LoadPlugin("C:\Avis\Tdeint.dll")
LoadPlugin("C:\Avis\Decomb.dll")
LoadPlugin("C:\Avis\KernelDeint140.dll")
#
#
#
#
#
# Programm
#
A = MPEG2Source("\Videos\School\School.d2v",idct=7,cpu=4)
B = MPASource("\Videos\School\School0ms.mpa",normalize = false)
AudioDub(A, B)
FadeIn(50)
FadeOut(50)
TDeint(type=3)
Crop(0,0,-20,0)
GaussResize(512,384,0,p=70)

Alles anzeigen

lg Oneboy1979

katjarella

ich würde es so machen:

Code

SetMemoryMax(64)
SetWorkingDir("H:\Doom9\t34345")


LoadPlugin("***\DGDecode.dll")		#MD5 97a00ef5ba1754488fab7f4702c8a5b6
LoadPlugin("***\NicAudio_v1.7.dll")	#MD5 d16d45cd918e297272322a2a19ce9077
LoadPlugin("***\TDeint.dll")		#MD5 3b3da7b0f59f1047e2b7770db51fb846


[COLOR='SeaGreen']#SOURCE[/COLOR]
video=MPEG2Source("Sample.d2v",cpu=6)
audio=NicMPASource("Sample T01 DELAY 0ms.mpa",2)
AudioDub(video,audio)
TDeint(order=1,type=2,slow=2)
GaussResize(512,384,0,0,-22,-3,p=62)
AudioNormalize()


[COLOR='#2e8b57']#je nach Encoder
#ConvertToYUY2()[/COLOR]


function AudioNormalize(clip c){
	left_ch = GetChannel(c,1).Normalize()
	right_ch = GetChannel(c,2).Normalize()
	va = MergeChannels(left_ch, right_ch).ResampleAudio(44100).ConvertAudioTo16bit()
	return AudioDub(c,va)
}

Alles anzeigen

evt. noch einen extraDeblockFilter, aber da kenn ich mich garnicht aus.

Oneboy1979

Zitat von katjarella

ich würde es so machen:

Code

SetMemoryMax(64)
SetWorkingDir("H:\Doom9\t34345")


LoadPlugin("***\DGDecode.dll")		#MD5 97a00ef5ba1754488fab7f4702c8a5b6
LoadPlugin("***\NicAudio_v1.7.dll")	#MD5 d16d45cd918e297272322a2a19ce9077
LoadPlugin("***\TDeint.dll")		#MD5 3b3da7b0f59f1047e2b7770db51fb846


[COLOR='SeaGreen']#SOURCE[/COLOR]
video=MPEG2Source("Sample.d2v",cpu=6)
audio=NicMPASource("Sample T01 DELAY 0ms.mpa",2)
AudioDub(video,audio)
TDeint(order=1,type=2,slow=2)
GaussResize(512,384,0,0,-22,-3,p=62)
AudioNormalize()


[COLOR='#2e8b57']#je nach Encoder
#ConvertToYUY2()[/COLOR]


function AudioNormalize(clip c){
	left_ch = GetChannel(c,1).Normalize()
	right_ch = GetChannel(c,2).Normalize()
	va = MergeChannels(left_ch, right_ch).ResampleAudio(44100).ConvertAudioTo16bit()
	return AudioDub(c,va)
}

Alles anzeigen

evt. noch einen extraDeblockFilter, aber da kenn ich mich garnicht aus.

Hi,

hab das script mal am laufen, sieht nicht so schlecht aus, nur die Verblockung ist ziemlich heftig, merkt man erst richtig wenn mans auf Vollbild anschaut.
Vielleicht weiß da noch wer was.

lg Oneboy1979

LigH

Dann schaut zuerst mal nach den MPEG2Source-Parametern, denke ich. Zum Beispiel fällt mir da "iPP" ein. Eventuell auch ganz vorsichtig die Thresholds verkleinern.

Didée

Hab' mal ein Multizweck-Framework genommen, und das Ding da 'reingestopft. Langsam isses (u.a. MV-Denoising) - ob's auch gut ist, kann ich jetzt gerade schlecht kontrollieren...

Ergebnis (4 MB, Xvid)

Code

[size=8]LoadPlugin("mt_masktools.dll")
LoadPlugin("RemoveGrain.dll")
LoadPlugin("MedianBlur.dll")
LoadPlugin("MVTools.dll")
LoadPlugin("FluxSmooth.dll")
LoadPlugin("ttempsmooth.dll")
LoadPlugin("TIVTC.dll")
LoadPlugin("vinverse.dll")


Import("Deblock_qed.avs")
Import("LimitedSharpen.avs")


mpeg2source("Sample.d2v") .crop(0,0,-16,-0,true)


# separatefields().trim(1,0).weave()
TFM(pp=0)


o = last
o


vinverse(3.0,amnt=12) #.turnleft().vinverse().turnright()
deblock_qed(quant1=30,quant2=30,aOff1=4,bOff1=8,aOff2=4,bOff2=8)
#vinverse() #.turnleft().vinverse().turnright()
base = last


 min1   = base .minblur(1)
 min2   = min1 .minblur(2)
 min2x  = mt_lutxy(min1,min2,"x 2 + y < x 2 + x 2 - y > x 2 - y ? ?",U=3,V=3)
 min2xx = mt_lutxy(min2x,min2x.fluxsmootht(7),"x 4 + y < x 1 + x 4 - y > x 1 - x 49 * y 51 * + 100 / ? ?",U=3,V=3)
  \ .removegrain(11)
render = base.mt_adddiff( mergeluma(mt_makediff(min2x,min2x.minblur(1,1)),mt_makediff(min2x,min2x.minblur(2,1)),0.51),U=2,V=2)
 
 # Parameter für Motion Search
 idx_1 = 11
 idx_2 = 12
 me    = 8
 bs    = 8
 lmbda = bs*bs*4
 pnw  = 32
 
 # Motion Search
 vec1_bw2 = min2xx.MVAnalyse(isb=true, truemotion=false,delta=2,lambda=lmbda,pel=2,searchparam=me,sharp=2,blksize=bs,overlap=bs/2,pnew=pnw,idx=idx_1)
 vec1_bw1 = min2xx.MVAnalyse(isb=true, truemotion=false,delta=1,lambda=lmbda,pel=2,searchparam=me,sharp=2,blksize=bs,overlap=bs/2,pnew=pnw,idx=idx_1)
 vec1_fw1 = min2xx.MVAnalyse(isb=false,truemotion=false,delta=1,lambda=lmbda,pel=2,searchparam=me,sharp=2,blksize=bs,overlap=bs/2,pnew=pnw,idx=idx_1)
 vec1_fw2 = min2xx.MVAnalyse(isb=false,truemotion=false,delta=2,lambda=lmbda,pel=2,searchparam=me,sharp=2,blksize=bs,overlap=bs/2,pnew=pnw,idx=idx_1)
 
 # Kompensation Analyseclip
 comp_bw2_flat = min2xx.MVCompensate(vec1_bw2, thSAD=bs*bs*80, idx=idx_1)
 comp_bw1_flat = min2xx.MVCompensate(vec1_bw1, thSAD=bs*bs*80, idx=idx_1)
 comp_fw1_flat = min2xx.MVCompensate(vec1_fw1, thSAD=bs*bs*80, idx=idx_1)
 comp_fw2_flat = min2xx.MVCompensate(vec1_fw2, thSAD=bs*bs*80, idx=idx_1)
 long_flat = interleave(comp_bw2_flat,comp_bw1_flat,min2xx,comp_fw1_flat,comp_fw2_flat)
 
 # Kompensation Arbeitsclip
 comp_bw2 = render.MVCompensate(vec1_bw2, thSAD=bs*bs*80, idx=idx_2)
 comp_bw1 = render.MVCompensate(vec1_bw1, thSAD=bs*bs*80, idx=idx_2)
 comp_fw1 = render.MVCompensate(vec1_fw1, thSAD=bs*bs*80, idx=idx_2)
 comp_fw2 = render.MVCompensate(vec1_fw2, thSAD=bs*bs*80, idx=idx_2)
 
 # Bewegungskompensiertes, nach Kompensationsqualität gewichtetes temporales Denoising
 TNR =  interleave(comp_bw2,comp_bw1,base,comp_fw1,comp_fw2)
  \    .ttempsmooth(2,8,8,2,2,strength=5,fp=true,pfclip=long_flat)
  \    .SelectEvery(5,2)
 
TNR .crop(0,0,-4,-4).limitedsharpen(ss_x=1.5*640/720,ss_y=1.5*480/576,dest_x=640,dest_y=480)


#interleave(o,last)
#stackhorizontal(o,last)


return(last)


###


# Nifty Gauss/Median combination
function MinBlur(clip clp, int r, int "uv")
{
uv   = default(uv,3)
uv2  = (uv==2) ? 1 : uv
rg4  = (uv==3) ? 4 : -1
rg11 = (uv==3) ? 11 : -1
rg20 = (uv==3) ? 20 : -1
medf = (uv==3) ? 1 : -200


RG11D = (r==1) ? mt_makediff(clp,clp.removegrain(11,rg11),U=uv2,V=uv2)
 \    : (r==2) ? mt_makediff(clp,clp.removegrain(11,rg11).removegrain(20,rg20),U=uv2,V=uv2)
 \    :          mt_makediff(clp,clp.removegrain(11,rg11).removegrain(20,rg20).removegrain(20,rg20),U=uv2,V=uv2)
RG4D  = (r==1) ? mt_makediff(clp,clp.removegrain(4,rg4),U=uv2,V=uv2)
 \    : (r==2) ? mt_makediff(clp,clp.medianblur(2,2*medf,2*medf),U=uv2,V=uv2)
 \    :          mt_makediff(clp,clp.medianblur(3,3*medf,3*medf),U=uv2,V=uv2)
DD    = mt_lutxy(RG11D,RG4D,"x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?",U=uv2,V=uv2)
clp.mt_makediff(DD,U=uv,V=uv)
return(last)
}[/size]

Alles anzeigen

Oneboy1979

Danke an alle. Didée ich werd mir das mal anschauen. Ergebnis sieht auf den ersten Blick voll ok aus.

lg Oneboy1979

Jetzt mitmachen!